Synchroniser l'heure locale de Windows avec le serveur MT5

prostotrader 2017.01.18 12:10 #11

Avez-vous d'autres suggestions ou commentaires sur le code ?

fxsaber 2017.01.18 12:11 #12

prostotrader:
C'est insignifiant (millisecondes) et ça flotte, je ne pense pas que ça fera "météo".

authorized on BCS-MetaTrader5 through Access Server #1 (ping: 50.30 ms)

Si vous obtenez une heure de tic-tac de 12:29:59.970, vous devez régler l'heure sur 12:30 exactement.

prostotrader 2017.01.18 12:13 #13

fxsaber:

authorized on BCS-MetaTrader5 through Access Server #1 (ping: 50.30 ms)

Si vous obtenez un temps de tic de 12:29:59.970, vous devez mettre le temps exactement à 12:30.

Oui, vous avez probablement un ping élevé (j'ai 4-6ms).

Quelle est la meilleure façon d'obtenir un ping ?

Ajouté par

Tout le monde connaît son ping moyen, il suffit peut-être de l'entrer comme une constante.

input ushort Ping = 5; //Средний пинг

Les courtiers ; est-ce L'Apprentissage Automatique dans le Intéressant et Humour

fxsaber 2017.01.18 12:23 #14

prostotrader:

Quelle est la meilleure façon d'obtenir un ping ?

TERMINAL_PING_LAST

prostotrader 2017.01.18 12:24 #15

fxsaber:
TERMINAL_PING_LAST

Merci, je ne savais pas, je vais le mettre dans le code.

fxsaber 2017.01.18 12:26 #16

// loc_time.wMilliseconds=ushort(ulong(curr_tick[0].time_msc)-ulong(curr_tick[0].time)*1000); // Было
loc_time.wMilliseconds=ushort(curr_tick[0].time_msc % 1000); // Стало

prostotrader 2017.01.18 13:19 #17

Merci à fxsaber pour ses précieux commentaires, voici ce qui en ressort

//+------------------------------------------------------------------+
//|                                              Time_sync_forts.mq5 |
//|                                      Copyright 2016 prostotrader |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016 prostotrader"
#property link      "https://www.mql5.com"
#property version   "1.00"
//---
struct _SYSTEMTIME
  {
   ushort            wYear;
   ushort            wMonth;
   ushort            wDayOfWeek;
   ushort            wDay;
   ushort            wHour;
   ushort            wMinute;
   ushort            wSecond;
   ushort            wMilliseconds;
  };

_SYSTEMTIME loc_time;

#import "kernel32.dll"
void GetLocalTime(_SYSTEMTIME &sys_time);
bool SetLocalTime(_SYSTEMTIME &sys_time);
#import
//---
bool is_sync;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   is_sync=false;
   MarketBookAdd(Symbol());
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   MarketBookRelease(Symbol());
  }
//+------------------------------------------------------------------+
//| Expert On book event function                                    |
//+------------------------------------------------------------------+
bool ConvertToTime(const long n_value,_SYSTEMTIME  &a_time)
  {
   a_time.wMilliseconds=ushort(n_value%1000);
   ulong new_time=(ulong(n_value)-ulong(a_time.wMilliseconds))/1000;
   MqlDateTime cur_time;
   cur_time.year=0;
   TimeToStruct(datetime(new_time),cur_time);
   if(cur_time.year>0)
     {
      a_time.wDay=ushort(cur_time.day);
      a_time.wDayOfWeek=ushort(cur_time.day_of_week);
      a_time.wHour=ushort(cur_time.hour);
      a_time.wMinute= ushort(cur_time.min);
      a_time.wMonth = ushort(cur_time.mon);
      a_time.wSecond= ushort(cur_time.sec);
      a_time.wYear=ushort(cur_time.year);
      return(true);
     }
   return(false);
  }
//+------------------------------------------------------------------+
//| Expert On book event function                                    |
//+------------------------------------------------------------------+
void OnBookEvent(const string &symbol)
  {
   loc_time.wYear=0;
   GetLocalTime(loc_time);
   if(loc_time.wYear>0)
     {
      if((loc_time.wHour==9) && (loc_time.wMinute>=50) && (loc_time.wMinute<=59))
        {
         MqlTick curr_tick[1];
         if(CopyTicks(symbol,curr_tick,COPY_TICKS_ALL,0,1)==1)
           {
            MqlDateTime sv_time;
            TimeToStruct(curr_tick[0].time,sv_time);
            if(!is_sync)
              {
               long last_ping=long(NormalizeDouble(double(TerminalInfoInteger(TERMINAL_PING_LAST))/1000,0));
               if((loc_time.wDayOfWeek==ushort(sv_time.day_of_week)) &&
                  (loc_time.wHour==ushort(sv_time.hour)))
                 {
                  long mcs_time=long(curr_tick[0].time_msc%1000);
                  if((mcs_time+last_ping)>999)
                    {
                     mcs_time=long(curr_tick[0].time_msc)+last_ping;
                     if(!ConvertToTime(mcs_time, loc_time)) return;
                    }
                  else
                    {
                     loc_time.wMinute = ushort(sv_time.min);
                     loc_time.wSecond = ushort(sv_time.sec);
                     loc_time.wMilliseconds=ushort(mcs_time);
                    }

                  if(SetLocalTime(loc_time))
                    {
                     is_sync=true;
                     Print("Local time sync is done.");
                    }
                 }
              }
           }
        }
      else is_sync=false;
     }
  }
//+------------------------------------------------------------------+

Synchronise Windows local time new mql4 providing millisecond Marché fermé

fxsaber 2017.01.18 14:20 #18

C'est un peu délicat, n'est-ce pas ? Je ne l'ai pas lu, c'est juste ça qui a attiré mon attention.

//   ulong new_time=(ulong(n_value)-ulong(a_time.wMilliseconds))/1000;
   ulong new_time=ulong(n_value / 1000);
   MqlDateTime cur_time = {0};
//   cur_time.year=0;

//.......
//               long last_ping=long(NormalizeDouble(double(TerminalInfoInteger(TERMINAL_PING_LAST))/1000,0));
             long last_ping=long(TerminalInfoInteger(TERMINAL_PING_LAST))/2000.0 + 0.5);

Synchronise Windows local time Erreurs, bugs, questions ECN, exécution des ordres,

prostotrader 2017.01.18 14:25 #19

fxsaber:
C'est un peu trop compliqué à mon goût. Je ne l'ai pas lu, c'est juste ça qui a attiré mon attention.

//   ulong new_time=(ulong(n_value)-ulong(a_time.wMilliseconds))/1000;
   ulong new_time=ulong(n_value / 1000);
   MqlDateTime cur_time = {0};
//   cur_time.year=0;

//.......
//               long last_ping=long(NormalizeDouble(double(TerminalInfoInteger(TERMINAL_PING_LAST))/1000,0));
             long last_ping=long(TerminalInfoInteger(TERMINAL_PING_LAST))/2000.0 + 0.5);

:)

//+------------------------------------------------------------------+
//|                                              Time_sync_forts.mq5 |
//|                                      Copyright 2016 prostotrader |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016 prostotrader"
#property link      "https://www.mql5.com"
#property version   "1.00"
//---
struct _SYSTEMTIME
  {
   ushort            wYear;
   ushort            wMonth;
   ushort            wDayOfWeek;
   ushort            wDay;
   ushort            wHour;
   ushort            wMinute;
   ushort            wSecond;
   ushort            wMilliseconds;
  };

_SYSTEMTIME loc_time;

#import "kernel32.dll"
void GetLocalTime(_SYSTEMTIME &sys_time);
bool SetLocalTime(_SYSTEMTIME &sys_time);
#import
//---
bool is_sync;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   is_sync=false;
   MarketBookAdd(Symbol());
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   MarketBookRelease(Symbol());
  }
//+------------------------------------------------------------------+
//| Expert On book event function                                    |
//+------------------------------------------------------------------+
bool ConvertToTime(const long n_value,_SYSTEMTIME  &a_time)
  {
   a_time.wMilliseconds=ushort(n_value%1000);
   ulong new_time=ulong(double(n_value)/1000);
   MqlDateTime cur_time = {0};
   TimeToStruct(datetime(new_time),cur_time);
   if(cur_time.year>0)
     {
      a_time.wDay=ushort(cur_time.day);
      a_time.wDayOfWeek=ushort(cur_time.day_of_week);
      a_time.wHour=ushort(cur_time.hour);
      a_time.wMinute= ushort(cur_time.min);
      a_time.wMonth = ushort(cur_time.mon);
      a_time.wSecond= ushort(cur_time.sec);
      a_time.wYear=ushort(cur_time.year);
      return(true);
     }
   return(false);
  }
//+------------------------------------------------------------------+
//| Expert On book event function                                    |
//+------------------------------------------------------------------+
void OnBookEvent(const string &symbol)
  {
   loc_time.wYear=0;
   GetLocalTime(loc_time);
   if(loc_time.wYear>0)
     {
      if((loc_time.wHour==9) && (loc_time.wMinute>=50) && (loc_time.wMinute<=59))
        {
         MqlTick curr_tick[1];
         if(CopyTicks(symbol,curr_tick,COPY_TICKS_ALL,0,1)==1)
           {
            MqlDateTime sv_time;
            TimeToStruct(curr_tick[0].time,sv_time);
            if(!is_sync)
              {
               long last_ping=long(NormalizeDouble(double(TerminalInfoInteger(TERMINAL_PING_LAST))/1000,0));
               if((loc_time.wDayOfWeek==ushort(sv_time.day_of_week)) &&
                  (loc_time.wHour==ushort(sv_time.hour)))
                 {
                  long mcs_time=long(curr_tick[0].time_msc%1000);
                  if((mcs_time+last_ping)>999)
                    {
                     mcs_time=long(curr_tick[0].time_msc)+last_ping;
                     if(!ConvertToTime(mcs_time, loc_time)) return;
                    }
                  else
                    {
                     loc_time.wMinute = ushort(sv_time.min);
                     loc_time.wSecond = ushort(sv_time.sec);
                     loc_time.wMilliseconds=ushort(mcs_time);
                    }

                  if(SetLocalTime(loc_time))
                    {
                     is_sync=true;
                     Print("Local time sync is done.");
                    }
                 }
              }
           }
        }
      else is_sync=false;
     }
  }
//+------------------------------------------------------------------+

Synchronise Windows local time new mql4 providing millisecond Marché fermé

fxsaber 2017.01.18 15:44 #20

Le ping doit également être divisé en deux - vous n'avez pas besoin d'un va-et-vient, juste d'un va-et-vient.

Synchroniser l'heure locale de Windows avec le serveur MT5 - page 2