交易品种保证金比率

MQL5 API 提供的交易品种规范的特性中，有几个与保证金要求相关的特性，这些特性在开立和维持交易头寸时适用，我们将在后面的章节中详细讨论。由于终端提供不同市场和不同类型金融工具的交易，这些要求可能会有很大差异。概括地说，其表现在保证金修正率的应用上，保证金修正率是针对各种交易品种和不同类型的交易运算单独设定的。对于用户，该比率显示在终端的 Specifications 窗口中。

正如我们将在下面看到的，乘数（如果应用的话）应与交易品种特性中的保证金值相乘。可以使用 SymbolInfoMarginRate 函数以编程方式获得保证金比率。

bool SymbolInfoMarginRate (const string symbol, ENUM_ORDER_TYPE orderType, double &initial, double &maintenance)

对于指定的交易品种和订单类型 (ENUM_ORDER_TYPE)，该函数分别用初始和维护保证金比率填充通过引用传递的 initial 和 maintenance 参数。由此获得的比率应乘以相应类型的保证金值（在保证金要求一节中介绍了如何请求保证金值），以获取在下订单（如 orderType）时应在帐户中保留的金额。

如果执行成功，则该函数返回 true。

让我们使用一个简单脚本 SymbolMarginRate.mq5 作为示例，该示例根据 MarketWatchOnly 参数输出 Market Watch 或所有可用交易品种的保证金比率。可以在 OrderType 参数中指定操作类型。

#include <MQL5Book/MqlError.mqh>

input bool MarketWatchOnly = true;
input ENUM_ORDER_TYPE OrderType = ORDER_TYPE_BUY;

void OnStart()
{
   const int n = SymbolsTotal(MarketWatchOnly);
   PrintFormat("Margin rates per symbol for %s:", EnumToString(OrderType));
   for(int i = 0; i < n; ++i)
   {
      const string s = SymbolName(i, MarketWatchOnly);
      double initial = 1.0, maintenance = 1.0;
      if(!SymbolInfoMarginRate(s, OrderType, initial, maintenance))
      {
         PrintFormat("Error: %s(%d)", E2S(_LastError), _LastError);
      }
      PrintFormat("%4d %s = %f %f", i, s, initial, maintenance);
   }
}

以下是其日志。

Margin rates per symbol for ORDER_TYPE_BUY:
   0 EURUSD = 1.000000 0.000000
   1 XAUUSD = 1.000000 0.000000
   2 BTCUSD = 0.330000 0.330000
   3 USDCHF = 1.000000 0.000000
   4 USDJPY = 1.000000 0.000000
   5 AUDUSD = 1.000000 0.000000
   6 USDRUB = 1.000000 1.000000

你可以将收到的值与终端中的交易品种规范进行比较。

交易和报价时段时间表

用于获取交易品种特性的函数概述