//+------------------------------------------------------------------+
//| DRAW_ZIGZAG.mq5 |
//| Copyright 2000-2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "Индикатор для демонстрации DRAW_ZIGZAG"
#property description "Рисует прямыми отрезками \"пилу\", пропуская бары одного дня"
#property description "День пропусков выбирается случайным образом при запуске индикатора"
#property description "Цвет, толщина и стиль отрезков меняется случайным"
#property description " образом через каждые N тиков"
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots 1
//--- plot ZigZag
#property indicator_label1 "ZigZag"
#property indicator_type1 DRAW_ZIGZAG
#property indicator_color1 clrBlue
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- input параметры
input int N=5; // кол-во тиков для изменения
//--- indicator buffers
double ZigZagBuffer1[];
double ZigZagBuffer2[];
//--- день недели, для которого индикатор не рисуется
int invisible_day;
//--- массив для хранения цветов
color colors[]={clrRed,clrBlue,clrGreen};
//--- массив для хранения стилей отрисовки линии
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- связывание массивов и индикаторных буферов
SetIndexBuffer(0,ZigZagBuffer1,INDICATOR_DATA);
SetIndexBuffer(1,ZigZagBuffer2,INDICATOR_DATA);
//--- получим случайное число от 0 до 6, для этого дня индикатор не рисуется
invisible_day=MathRand()%6;
//--- значение 0 (пустое значение) не будет участвовать в отрисовке
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- значение 0 (пустое значение) не будет участвовать в отрисовке
PlotIndexSetString(0,PLOT_LABEL,"ZigZag1;ZigZag2");
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- считаем тики для изменения стиля, цвета и толщины линии
ticks++;
//--- если накопилось достаточное число тиков
if(ticks>=N)
{
//--- меняем свойства линии
ChangeLineAppearance();
//--- сбрасываем счетчик тиков в ноль
ticks=0;
}
//--- структура времени понадобится для получения дня недели каждого бара
MqlDateTime dt;
//--- позиция начала расчетов
int start=0;
//--- если индикатор рассчитывался на предыдущем тике, то начинаем расчет с предпоследнего
if(prev_calculated!=0) start=prev_calculated-1;
//--- цикл расчетов
for(int i=start;i<rates_total;i++)
{
//--- запишем время открытия бара в структуру
TimeToStruct(time[i],dt);
//--- если день недели этого бара равен invisible_day
if(dt.day_of_week==invisible_day)
{
//--- запишем пустые значения в буферы для этого бара
ZigZagBuffer1[i]=0;
ZigZagBuffer2[i]=0;
}
//--- если день недели подходящий, то заполняем буферы
else
{
//--- если номер бара четный
if(i%2==0)
{
//--- пишем в 1-ый буфер High, во 2-ой Low
ZigZagBuffer1[i]=high[i];
ZigZagBuffer2[i]=low[i];
}
//--- номер бара нечетный
else
{
//--- заполняем бар в обратном порядке
ZigZagBuffer1[i]=low[i];
ZigZagBuffer2[i]=high[i];
}
}
}
//--- return value of prev_calculated for next call
return(rates_total);
}
//+------------------------------------------------------------------+
//| Изменяет внешний вид отрезков в зигзаге |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- строка для формирования информации о свойствах ZigZag
string comm="";
//--- блок изменения цвета зигзага
int number=MathRand(); // получим случайное число
//--- делитель числа равен размеру массива colors[]
int size=ArraySize(colors);
//--- получим индекс для выбора нового цвета как остаток от целочисленного деления
int color_index=number%size;
//--- установим цвет как свойство PLOT_LINE_COLOR
PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- запишем цвет линии
comm=comm+"\r\n"+(string)colors[color_index];
//--- блок изменения толщины линии
number=MathRand();
//--- получим толщину как остаток от целочисленного деления
int width=number%5; // толщина задается от о до 4
//--- установим цвет как свойство PLOT_LINE_WIDTH
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- запишем толщину линии
comm=comm+"\r\nWidth="+IntegerToString(width);
//--- блок изменения стиля линии
number=MathRand();
//--- делитель числа равен размеру массива styles
size=ArraySize(styles);
//--- получим индекс для выбора нового стиля как остаток от целочисленного деления
int style_index=number%size;
//--- установим цвет как свойство PLOT_LINE_COLOR
PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- запишем стиль линии
comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- добавим информацию о дне, который пропускается в расчетах
comm="\r\nНеотрисовываемый день - "+EnumToString((ENUM_DAY_OF_WEEK)invisible_day)+comm;
//--- выведем информацию на график через комментарий
Comment(comm);
}
|
