Справочник MQL5Пользовательские индикаторыСтили индикаторов в примерахDRAW_SECTION

DRAW_SECTION

Стиль DRAW_SECTION рисует заданным цветом отрезки по значениям индикаторного буфера. Толщину, цвет и стиль отображения линии можно задавать так же, как и для стиля DRAW_LINE – директивами компилятора или динамически с помощью функции PlotIndexSetInteger(). Динамическое изменение свойств графического построения позволяет "оживить" индикаторы, чтобы они меняли свой вид в зависимости от текущей ситуации.

Секции рисуются от одного непустого значения до другого непустого значения индикаторного буфера, пустые значения пропускаются. Чтобы указать, какое значение следует считать "пустым", установите это значение в свойстве PLOT_EMPTY_VALUE. Например, если индикатор должен рисоваться отрезками по ненулевым значениям, то нужно задать нулевое значение в качестве пустого:

//--- значение 0 (пустое значение) не будет участвовать в отрисовке
PlotIndexSetDouble(индекс_построения_DRAW_SECTION,PLOT_EMPTY_VALUE,0);

Всегда явно заполняйте значениями все элементы индикаторного буфера, неотрисовываемым элементам задавайте пустое значение.

Количество требуемых буферов для построения DRAW_SECTION — 1.

Пример индикатора, рисующего отрезки между ценами High и Low. Цвет, толщина и стиль всех секций меняются случайным образом каждые N тиков.

Пример стиля DRAW_SECTION

Обратите внимание, первоначально для графического построения plot1 со стилем DRAW_SECTION свойства задаются с помощью директивы компилятора #property, а затем в функции OnCalculate() эти три свойства задаются случайным образом. Параметр N вынесен во внешние параметры индикатора для возможности ручной установки (закладка "Параметры" в окне свойств индикатора).

//+------------------------------------------------------------------+
//|                                                 DRAW_SECTION.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"

#property description "Индикатор для демонстрации DRAW_SECTION"
#property description "Рисует прямыми отрезками через каждые bars баров"
#property description "Цвет, толщина и стиль секций меняется случайным образом"
#property description "через каждые N тиков"

#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1
//--- plot Section
#property indicator_label1  "Section"
#property indicator_type1   DRAW_SECTION
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- input параметр
input int      bars=5;           // длина секций в барах
input int      N=5;              // кол-во тиков для изменения стиля секций
//--- индикаторный буфер для построения
double         SectionBuffer[];
//--- вспомогательная переменная для вычисления концов секций
int            divider;
//--- массив для хранения цветов
color colors[]={clrRed,clrBlue,clrGreen};
//--- массив для хранения стилей отрисовки линии
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- связывание массива и индикаторного буфера
   SetIndexBuffer(0,SectionBuffer,INDICATOR_DATA);
//--- значение 0 (пустое значение) не будет участвовать в отрисовке
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- проверим параметр индикатора
   if(bars<=0)
     {
      PrintFormat("Недопустимое значение параметра bar=%d",bars);
      return(INIT_PARAMETERS_INCORRECT);
     }
   else divider=2*bars;
//---+
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- считаем тики для изменения стиля, цвета и толщины линии
   ticks++;
//--- если накопилось критическое число тиков
   if(ticks>=N)
     {
      //--- меняем свойства линии
      ChangeLineAppearance();
      //--- сбрасываем счетчик тиков в ноль
      ticks=0;
     }

//--- номер бара, с которого начнем расчет значений индикатора
   int start=0;
//--- если индикатор уже рассчитывали раньше, то установим start на предыдущий бар
   if(prev_calculated>0) start=prev_calculated-1;
//--- здесь все расчеты значений индикатора
   for(int i=start;i<rates_total;i++)
     {
      //--- получим остаток от деления номера бара на 2*bars
      int rest=i%divider;
      //--- если номер бара делится без остатка на 2*bars
      if(rest==0)
        {
         //--- конец отрезка установим на цену High этого бара
         SectionBuffer[i]=high[i];
        }
      //--- если остаток от деления равен bars,
      else
        {
         //--- конец отрезка установим на цену High этого бара
         if(rest==bars) SectionBuffer[i]=low[i];
         //--- если ничего не подошло, то этот бар пропускаем - ставим значение 0
         else SectionBuffer[i]=0;
        }
     }
//--- вернем значение prev_calculated для следующего вызова функции
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Изменяет внешний вид секций в индикаторе                         |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- строка для формирования информации о свойствах линии
   string comm="";
//--- блок изменения цвета линии
   int number=MathRand(); // получим случайное число
//--- делитель числа равен размеру массива colors[]
   int size=ArraySize(colors);
//--- получим индекс для выбора нового цвета как остаток от целочисленного деления
   int color_index=number%size;
//--- установим цвет как свойство PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- запишем цвет линии
   comm=comm+"\r\n"+(string)colors[color_index];

//--- блок изменения толщины линии
   number=MathRand();
//--- получим толщину как остаток от целочисленного деления
   int width=number%5;   // толщина задается от о до 4
//--- установим толщину
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- запишем толщину линии
   comm=comm+"\r\nWidth="+IntegerToString(width);

//--- блок изменения стиля линии
   number=MathRand();
//--- делитель числа равен размеру массива styles
   size=ArraySize(styles);
//--- получим индекс для выбора нового стиля как остаток от целочисленного деления
   int style_index=number%size;
//--- установим стиль линий
   PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- запишем стиль линии
   comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- выведем информацию на график через комментарий
   Comment(comm);
  }

DRAW_LINE

DRAW_HISTOGRAM