Visibilidade de Objetos

void OnStart()
  {
//---
   string highlevel="PreviousDayHigh";
   string lowlevel="PreviousDayLow";
   double prevHigh;           // O Máxima do dia anterior
   double prevLow;            // O Mínimo do dia anterior
   double highs[],lows[];     // Arrays de Máximo e Mínimo
 
//--- redefine o código de erro
   ResetLastError();
//--- Obtém os 2 últimos valores de Máximo na janela de tempo diária
   int highsgot=CopyHigh(Symbol(),PERIOD_D1,0,2,highs);
   if(highsgot>0) // Se cópia foi bem sucedida
     {
      Print("Os preços em alta dos últimos dois dias foram obtidos com sucesso");
      prevHigh=highs[0]; // O Máximo do dia anterior
      Print("prevHigh = ",prevHigh);
      if(ObjectFind(0,highlevel)<0) // Objeto com o mesmo highlevel não encontrado
        {
         ObjectCreate(0,highlevel,OBJ_HLINE,0,0,0); // Cria o objeto de linha Horizontal
        }
      //--- Define valor para nível de preço para a linha highlevel
      ObjectSetDouble(0,highlevel,OBJPROP_PRICE,0,prevHigh);
      //--- Define a visibilidade apenas para PERIOD_M10 e PERIOD_H4
      ObjectSetInteger(0,highlevel,OBJPROP_TIMEFRAMES,OBJ_PERIOD_M10|OBJ_PERIOD_H4);
     }
   else
     {
      Print("Não foi possível obter preços em lata nos últimos dois dias, Erro = ",GetLastError());
     }
 
//--- redefine o código de erro
   ResetLastError();
//--- Obtém os 2 últimos valores de Mínimo na janela de tempo diária
   int lowsgot=CopyLow(Symbol(),PERIOD_D1,0,2,lows);
   if(lowsgot>0) // Se cópia foi bem sucedida
     {
      Print("Os preços em baixa dos últimos dois dias foram obtidos com sucesso");
      prevLow=lows[0]; // O Mínimo do dia anterior
      Print("prevLow = ",prevLow);
      if(ObjectFind(0,lowlevel)<0) // Objeto com o mesmo lowlevel não encontrado
        {
         ObjectCreate(0,lowlevel,OBJ_HLINE,0,0,0); // Cria o objeto linha Horizontal
        }
      //--- Define valor para o nível de preço para a linha lowlevel
      ObjectSetDouble(0,lowlevel,OBJPROP_PRICE,0,prevLow);
      //--- Define a visibilidade apenas para PERIOD_M10 e PERIOD_H4
      ObjectSetInteger(0,lowlevel,OBJPROP_TIMEFRAMES,OBJ_PERIOD_M10|OBJ_PERIOD_H4);
     }
   else Print("Não foi possível obter preços em baixa nos últimos dois dias, Erro = ",GetLastError());
 
   ChartRedraw(0); // redesenha o gráfico de forma forçada
  }