Visibilidad de objetos

void OnStart()
  {
//---
   string highlevel="PreviousDayHigh";
   string lowlevel="PreviousDayLow";
   double prevHigh;           // High del día anterior
   double prevLow;            // Low del día anterior
   double highs[],lows[];     // matrices para recibir High y Low
 
//--- ponemos el último error a cero
   ResetLastError();
//--- obtenemos 2 últimos valores High en período de tiempo diurno
   int highsgot=CopyHigh(Symbol(),PERIOD_D1,0,2,highs);
   if(highsgot>0) // si el copiado ha sido con éxito
     {
      Print("Precios High de los últimos 2 días han sido recibidos con éxito");
      prevHigh=highs[0]; // High del día anterior
      Print("prevHigh = ",prevHigh);
      if(ObjectFind(0,highlevel)<0) // objeto con el nombre highlevel no ha sido encontrado
        {
         ObjectCreate(0,highlevel,OBJ_HLINE,0,0,0); // creamos el objeto Línea Horizontal
        }
      //--- definimos el nivel de precio para la línea highlevel
      ObjectSetDouble(0,highlevel,OBJPROP_PRICE,0,prevHigh);
      //--- establecemos la visibilidad sólo para PERIOD_M10 y PERIOD_H4
      ObjectSetInteger(0,highlevel,OBJPROP_TIMEFRAMES,OBJ_PERIOD_M10|OBJ_PERIOD_H4);
     }
   else
     {
      Print("Fallo al recibir los precios High de los últimos 2 días, Error = ",GetLastError());
     }
 
//--- ponemos el último error a cero
   ResetLastError();
//--- obtenemos 2 últimos valores Low en período de tiempo diurno
   int lowsgot=CopyLow(Symbol(),PERIOD_D1,0,2,lows);
   if(lowsgot>0) // si el copiado ha sido con éxito
     {
      Print("Precios Low de los últimos 2 días han sido recibidos con éxito");
      prevLow=lows[0]; // Low del día anterior
      Print("prevLow = ",prevLow);
      if(ObjectFind(0,lowlevel)<0) // objeto con el nombre lowlevel no ha sido encontrado
        {
         ObjectCreate(0,lowlevel,OBJ_HLINE,0,0,0); // creamos el objeto Línea Horizontal
        }
      //--- definimos el nivel de precio para la línea lowlevel
      ObjectSetDouble(0,lowlevel,OBJPROP_PRICE,0,prevLow);
      //--- establecemos la visibilidad sólo para  PERIOD_M10 y PERIOD_H4
      ObjectSetInteger(0,lowlevel,OBJPROP_TIMEFRAMES,OBJ_PERIOD_M10|OBJ_PERIOD_H4);
     }
   else Print("Fallo al recibir los precios Low de los últimos 2 días, Error = ",GetLastError());
 
   ChartRedraw(0); // redibujamos el gráfico por vía forzada
  }