Demo_FileGetInteger - script para MetaTrader 5

O script abre um arquivo localizado na pasta local do terminal e exibe valores de suas propriedades. A posição da pasta local do terminal pode ser obtida chamando a função TerminalInfoString().

PrintFormat("O caminho para a pasta local do terminal: %s\\Arquivos\\",TerminalInfoString(TERMINAL_DATA_PATH)); 

Este script demonstra o exemplo de utilização da primeira variante da função FileGetInteger(), de modo que exibe os valores das suas propriedades. Para a segunda variante da função, apenas as cinco primeiras propriedades estão disponíveis.

Código:

//--- exibe a janela dos parâmetros de entrada ao lançar o script
#property script_show_inputs
//--- parâmetros de entrada
input string InpFileName="dados.csv";
input string InpDirectoryName="AlgumaPasta";
//+------------------------------------------------------------------+
//| Função iniciar do Script de programa                             |
//+------------------------------------------------------------------+
void OnStart()
  {
   string path=InpDirectoryName+"//"+InpFileName;
   long   l=0;
//--- abrir o arquivo
   ResetLastError();
   int handle=FileOpen(path,FILE_READ|FILE_CSV);
   if(handle!=INVALID_HANDLE)
     {
      //--- imprimir todas as informações sobre o arquivo
      Print(InpFileName," informação do arquivo:");
      FileInfo(handle,FILE_EXISTS,l,"bool");
      FileInfo(handle,FILE_CREATE_DATE,l,"data");
      FileInfo(handle,FILE_MODIFY_DATE,l,"data");
      FileInfo(handle,FILE_ACCESS_DATE,l,"data");
      FileInfo(handle,FILE_SIZE,l,"outros");
      FileInfo(handle,FILE_POSITION,l,"outros");
      FileInfo(handle,FILE_END,l,"bool");
      FileInfo(handle,FILE_IS_COMMON,l,"bool");
      FileInfo(handle,FILE_IS_TEXT,l,"bool");
      FileInfo(handle,FILE_IS_BINARY,l,"bool");
      FileInfo(handle,FILE_IS_CSV,l,"bool");
      FileInfo(handle,FILE_IS_ANSI,l,"bool");
      FileInfo(handle,FILE_IS_READABLE,l,"bool");
      FileInfo(handle,FILE_IS_WRITABLE,l,"bool");
      //--- fechar o arquivo
      FileClose(handle);
     }
   else
      PrintFormat("%s arquivo não abriu, Erro Código = %d",InpFileName,GetLastError());
  }
//+------------------------------------------------------------------+
//| exibir o valor da propriedade de arquivo                         |
//+------------------------------------------------------------------+
void FileInfo(const int handle,const ENUM_FILE_PROPERTY_INTEGER id,
              long l,const string type)
  {
//--- obter o valor da propriedade
   ResetLastError();
   if((l=FileGetInteger(handle,id))!=-1)
     {
      //---  exibir o valor recebido no formato correto
      if(!StringCompare(type,"bool"))
         Print(EnumToString(id)," = ",l ? "verdadeiro" : "falso");
      if(!StringCompare(type,"data"))
         Print(EnumToString(id)," = ",(datetime)l);
      if(!StringCompare(type,"outros"))
         Print(EnumToString(id)," = ",l);
     }
   else
      Print("Erro, Código = ",GetLastError());
  }