Demo_FileGetInteger - Skript für den MetaTrader 5

Das Skript öffnet eine Datei, die sich im lokalen Terminalordner befindet und zeigt Werte mit seinen Eigenschaften an. Der Ort des lokalen Terminal-Ordners kann durch Aufruf der TerminalInfoString() Funktion festgestellt werden.

PrintFormat("Der Pfad zum lokalen Terminal-Ordner lautet: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH)); 

Das Skript demonstriert ein Beispiel für die Verwendung der FileGetInteger() Funktion, zeigt daher Werte mit seinen Eigenschaften an. In der zweiten Variante der Funktion werden nur die ersten fünf verfügbaren Eigenschaften angezeigt.

Code:

//--- Zeige Fenster mit den Eingabeparametern, wenn Sie das Skript starten
#property script_show_inputs
Eingabeparameter:
input string InpFileName="data.csv";
input string InpDirectoryName="GleicherOrdner";
//+------------------------------------------------------------------+
//| Skript Programmstart Funktion                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   string path=InpDirectoryName+"//"+InpFileName;
   long   l=0;
//--- Datei öffnen
   ResetLastError();
   int handle=FileOpen(path,FILE_READ|FILE_CSV);
   if(handle!=INVALID_HANDLE)
     {
      //--- Alle Informationen über die Datei ausgeben
      Print(InpFileName," Dateiinfo:");
      FileInfo(handle,FILE_EXISTS,l,"bool");
      FileInfo(handle,FILE_CREATE_DATE,l,"date");
      FileInfo(handle,FILE_MODIFY_DATE,l,"date");
      FileInfo(handle,FILE_ACCESS_DATE,l,"date");
      FileInfo(handle,FILE_SIZE,l,"other");
      FileInfo(handle,FILE_POSITION,l,"other");
      FileInfo(handle,FILE_END,l,"bool");
      FileInfo(handle,FILE_IS_COMMON,l,"bool");
      FileInfo(handle,FILE_IS_TEXT,l,"bool");
      FileInfo(handle,FILE_IS_BINARY,l,"bool");
      FileInfo(handle,FILE_IS_CSV,l,"bool");
      FileInfo(handle,FILE_IS_ANSI,l,"bool");
      FileInfo(handle,FILE_IS_READABLE,l,"bool");
      FileInfo(handle,FILE_IS_WRITABLE,l,"bool");
      //--- Datei schließen
      FileClose(handle);
     }
   else
      PrintFormat("%s Datei nicht geöffnet, FehlerCode = %d",InpFileName,GetLastError());
  }
//+------------------------------------------------------------------+
//| Anzeigen der Werte der Dateieigenschaft                          |
//+------------------------------------------------------------------+
void FileInfo(const int handle,const ENUM_FILE_PROPERTY_INTEGER id,
              long l,const string type)
  {
//--- Hole den Eigenschaftswert
   ResetLastError();
   if((l=FileGetInteger(handle,id))!=-1)
     {
      //--- Wert erhalten, im korrekten Format anzeigen
      if(!StringCompare(type,"bool"))
         Print(EnumToString(id)," = ",l ? "true" : "false");
      if(!StringCompare(type,"date"))
         Print(EnumToString(id)," = ",(datetime)l);
      if(!StringCompare(type,"other"))
         Print(EnumToString(id)," = ",l);
     }
   else
      Print("Fehler, Code = ",GetLastError());
  }