//+--------------------------------------------------------------------------------+
//| DRAW_LINE.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+--------------------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "Un indicatore per dimostrare DRAW_LINE"
#property description "Disegna una linea di un colore specificato ai prezzi Close"
#property description "Colore, spessore e stile della linea vengono cambiati casualmente"
#property description "dopo ogni N ticks"
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots 1
//--- Le proprietà della linea vengono impostate utilizzando le direttive del compilatore
#property indicator_label1 "Line" // Nome del disegno per la Finestra Dati
#property indicator_type1 DRAW_LINE // Tipo di disegno della linea
#property indicator_color1 clrRed // Colore della linea
#property indicator_style1 STYLE_SOLID // Stile della linea
#property indicator_width1 1 // Spessore della linea
//--- parametri input
input int N=5; // Numero di ticks da cambiare
//--- Un buffer indicatore per il disegno
double LineBuffer[];
//--- Un array per salvare i colori
color colors[]={clrRed,clrBlue,clrGreen};
//--- Un array per memorizzare gli stili di linea
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+--------------------------------------------------------------------------------+
//| Funzione di inizializzazione Indicatore Personalizzato |
//+--------------------------------------------------------------------------------+
int OnInit()
{
//--- Associa un array e un buffer indicatore
SetIndexBuffer(0,LineBuffer,INDICATOR_DATA);
//--- Inizializzazione del generatore di numeri pseudo-casuali
MathSrand(GetTickCount());
//---
return(INIT_SUCCEEDED);
}
//+--------------------------------------------------------------------------------+
//| Funzione di iterazione indicatore personalizato |
//+--------------------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- Calcola i ticks per cambiare lo stile, il colore e lo spessore della linea
ticks++;
//--- Se un numero critico di ticks è stato accumulato
if(ticks>=N)
{
//--- Cambia le proprietà della linea
ChangeLineAppearance();
//--- Resetta il contatore dei ticks a zero
ticks=0;
}
//--- Blocco per il calcolo dei valori dell'indicatore
for(int i=0;i<rates_total;i++)
{
LineBuffer[i]=close[i];
}
//--- Restituisce il valore prev_calculated per la successiva chiamata della funzione
return(rates_total);
}
//+--------------------------------------------------------------------------------+
//| Modifica l'aspetto della linea disegnata nell'indicatore |
//+--------------------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- Una stringa per la formazione di informazioni sulle proprietà di linea
string comm="";
//--- Un blocco per cambiare il colore della linea
//--- Ottiene un numero casuale
int number=MathRand();
//--- Il divisore è uguale alla grandezza dell'array colors []
int size=ArraySize(colors);
//--- Ottiene l'indice per selezionare un nuovo colore, come il resto della divisione intera
int color_index=number%size;
//--- Imposta il colore come la proprietà PLOT_LINE_COLOR
PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- Scrive il colore della linea
comm=comm+(string)colors[color_index];
//--- Un blocco per modificare la larghezza della linea
number=MathRand();
//--- Ottiene la larghezza del resto della divisione intera
int width=number%5; // Lo spessore è impostato da 0 a 4
//--- Imposta il colore come proprietà PLOT_LINE_WIDTH
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- Scrive lo spessore della linea
comm=comm+", Width="+IntegerToString(width);
//--- Un blocco per cambiare lo stile della linea
number=MathRand();
//--- Il divisore è uguale alla grandezza dell'array styles
size=ArraySize(styles);
//--- Ottiene l'indice per selezionare un nuovo stile, come resto della divisione intera
int style_index=number%size;
//--- Imposta il colore come la proprietà PLOT_LINE_COLOR
PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- Scrive lo stile della linea
comm=EnumToString(styles[style_index])+", "+comm;
//--- Imposta le informazioni del grafico usando un commento
Comment(comm);
}
|