OnCalculate

int  OnCalculate(
   const int        rates_total,       // price[] 배열 크기
   const int        prev_calculated,   // 이전 호출의 처리 막대 수
   const int        begin,             // price[] 배열의 인덱스 번호의 의미 있는 데이터는 다음에서 시작합니다
   const double&    price[]            // 계산할 값의 배열
   );

int  OnCalculate(
   const int        rates_total,       // 입력 시계열 크기
   const int        prev_calculated,   // 이전 호출의 처리 막대 수
   const datetime&  time{},            // 시간 배열
   const double&    open[],            // 배열 열기
   const double&    high[],            // 고가 배열
   const double&    low[],             // 저가 배열
   const double&    close[],           // 종가 배열
   const long&      tick_volume[],     // 틱 볼륨 배열
   const long&      volume[],          // 실수 볼륨 배열
   const int&       spread[]           // 스프레드 배열
   );

//+------------------------------------------------------------------+
//|                                           OnCalculate_Sample.mq5 |
//|                        Copyright 2018, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "샘플 모멘텀 지표 계산"
 
//---- 지표 설정
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots   1
#property indicator_type1   DRAW_LINE
#property indicator_color1  Blue
//---- 입력
input int MomentumPeriod=14; // 계산 주기
//---- 지표 버퍼
double    MomentumBuffer[];
//--- 계산 주기를 저장을 위한 글로벌 변수
int       IntPeriod;
//+------------------------------------------------------------------+
//| 사용자 지정 지표 초기화 함수                         |
//+------------------------------------------------------------------+
void OnInit()
  {
//--- 입력 매개변수를 확인
   if(MomentumPeriod<0)
     {
      IntPeriod=14;
      Print("주기 매개변수 값이 잘못되었습니다. 다음 값은 계산에서 사용됩니다 ",IntPeriod);
     }
   else
      IntPeriod=MomentumPeriod;
//---- 버퍼  
   SetIndexBuffer(0,MomentumBuffer,INDICATOR_DATA);
//---- DataWindow 및 하위 창에 표시할 지표 이름
   IndicatorSetString(INDICATOR_SHORTNAME,"Momentum"+"("+string(IntPeriod)+")");
//--- 그리기가 시작되는 막대의 인덱스를 설정
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,IntPeriod-1);
//--- 0.0을 그려지지 않은 빈 값으로 설정
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);
//--- 지표 정확도 표시
   IndicatorSetInteger(INDICATOR_DIGITS,2);
  }
//+------------------------------------------------------------------+
//|  모멘텀 지표 계산                                  |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,     // price[] 배열 크기 
                const int prev_calculated, // 이전에 처리한 막대의 수
                const int begin,           // 중요한 데이터가 시작되는 지점 
                const double &price[])     // 처리를 위한 값 배열
  {
//--- 계산을 위한 초기 포지션
   int StartCalcPosition=(IntPeriod-1)+begin;
//---- 계산 데이터가 충분하지 않은 경우
   if(rates_total<StartCalcPosition)
      return(0);  // 0 값을 사용하여 종료 - 지표가 계산되지 않음
//--- 정확한 그리기 시작
   if(begin>0)
      PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,StartCalcPosition+(IntPeriod-1));
//--- 시작 포지션을 정의하는 계산 시작
   int pos=prev_calculated-1;
   if(pos<StartCalcPosition)
      pos=begin+IntPeriod;
//--- 주 계산 루프
   for(int i=pos;i<rates_total && !IsStopped();i++)
      MomentumBuffer[i]=price[i]*100/price[i-IntPeriod];
//--- OnCalculate 실행이 완료되었습니다. 후속 호출에 대해 새 prev_calculated 값을 반환
   return(rates_total);
  }