//+------------------------------------------------------------------+
//| Demo_iIchimoku.mq5 |
//| Copyright 2000-2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "Gösterge, iVolumes teknik göstergesi için tamponlardan"
#property description "nasıl veri alınacağını göstermektedir."
#property description "Göstergenin hesaplanmasında kullanılacak sembol ve periyot,"
#property description "symbol ve period parametreleri ile ayarlanır."
#property description "İşleyicinin oluşturulması yöntemi 'type' parametresi ile ayarlanır (fonksiyon tipi)."
#property description "Diğer tüm parametreler standart Ichimoku Kinko Hyo göstergesindeki gibidir."
#property indicator_chart_window
#property indicator_buffers 5
#property indicator_plots 4
//--- Tenkan_sen grafiği
#property indicator_label1 "Tenkan_sen"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- Kijun_sen grafiği
#property indicator_label2 "Kijun_sen"
#property indicator_type2 DRAW_LINE
#property indicator_color2 clrBlue
#property indicator_style2 STYLE_SOLID
#property indicator_width2 1
//--- Senkou_Span grafiği
#property indicator_label3 "Senkou Span A;Senkou Span B" // bu iki alan Veri Penceresinde gösterilecek
#property indicator_type3 DRAW_FILLING
#property indicator_color3 clrSandyBrown, clrThistle
#property indicator_style3 STYLE_SOLID
#property indicator_width3 1
//--- Chikou_Span grafiği
#property indicator_label4 "Chikou_Span"
#property indicator_type4 DRAW_LINE
#property indicator_color4 clrLime
#property indicator_style4 STYLE_SOLID
#property indicator_width4 1
//+------------------------------------------------------------------+
//| İşleyici oluşturma yöntemleri için bir sayım |
//+------------------------------------------------------------------+
enum Creation
{
Call_iIchimoku, // iIchimoku kullan
Call_IndicatorCreate // IndicatorCreate kullan
};
//--- giriş parametreleri
input Creation type=Call_iIchimoku; // fonksiyon tipi
input int tenkan_sen=9; // Tenkan-sen periyodu
input int kijun_sen=26; // Kijun-sen periyodu
input int senkou_span_b=52; // Senkou Span B periyodu
input string symbol=" "; // sembol
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // zaman aralığı
//--- gösterge tamponu
double Tenkan_sen_Buffer[];
double Kijun_sen_Buffer[];
double Senkou_Span_A_Buffer[];
double Senkou_Span_B_Buffer[];
double Chinkou_Span_Buffer[];
//--- iIchimoku göstergesinin tanıtıcı değerini saklamak için bir değişken
int handle;
//--- kayıt için değişken
string name=symbol;
//--- çizelge üzerindeki gösterge ismi
string short_name;
//--- Ichimoku Kinko Hyo göstergesindeki değerlerin sayısını koruyacağız
int bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- dizilerin gösterge tamponlarına atanması
SetIndexBuffer(0,Tenkan_sen_Buffer,INDICATOR_DATA);
SetIndexBuffer(1,Kijun_sen_Buffer,INDICATOR_DATA);
SetIndexBuffer(2,Senkou_Span_A_Buffer,INDICATOR_DATA);
SetIndexBuffer(3,Senkou_Span_B_Buffer,INDICATOR_DATA);
SetIndexBuffer(4,Chinkou_Span_Buffer,INDICATOR_DATA);
//--- kijun_sen çubuklarının Senkou Span kanalının ileriye doğru kaydırma değeri
PlotIndexSetInteger(2,PLOT_SHIFT,kijun_sen);
//--- Chikou data Span, bir kaydırma değeri ile zaten iIchimoku içinde kayıtlı olduğundan
//--- Chinkou Span çizgisine bir kaydırma değeri ayarlanması gerekmiyor
//--- göstergenin çizileceği sembolü ayarla
name=symbol;
//--- sağa ve sola doğru olan boşlukları sil
StringTrimRight(name);
StringTrimLeft(name);
//--- sonuçta 'name' dizgisi sıfır uzunluğa sahipse
if(StringLen(name)==0)
{
//--- göstergenin tutturulduğu çizelge sembolünü al
name=_Symbol;
}
//--- göstergenin tanıtıcı değerini oluştur
if(type==Call_iIchimoku)
handle=iIchimoku(name,period,tenkan_sen,kijun_sen,senkou_span_b);
else
{
//--- yapıyı gösterge parametreleriyle doldur
MqlParam pars[3];
//--- Alligator çizgilerinin periyodları ve kaydırma değerleri
pars[0].type=TYPE_INT;
pars[0].integer_value=tenkan_sen;
pars[1].type=TYPE_INT;
pars[1].integer_value=kijun_sen;
pars[2].type=TYPE_INT;
pars[2].integer_value=senkou_span_b;
//--- işleyiciyi oluştur
handle=IndicatorCreate(name,period,IND_ICHIMOKU,3,pars);
}
//--- işleyici oluşturulmadıysa
if(handle==INVALID_HANDLE)
{
//--- hatayı belirt ve hata kodunu al
PrintFormat("iIchimoku göstergesinin tanıtıcı değeri, %s/%s sembolü için oluşturulamadı, hata kodu %d",
name,
EnumToString(period),
GetLastError());
//--- gösterge erken durduruldu
return(INIT_FAILED);
}
//--- Ichimoku Kinko Hyo göstergesinin hesaplandığı sembol ve zaman aralığı değerlerini göster
short_name=StringFormat("iIchimoku(%s/%s, %d, %d ,%d)",name,EnumToString(period),
tenkan_sen,kijun_sen,senkou_span_b);
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- göstergenin normal yolla başlatılması
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- iIchimoku göstergesinden kopyalanan değerlerin sayısı
int values_to_copy;
//--- göstergede hesaplanan değerlerin sayısını belirle
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() %d dönüşü yaptı, hata kodu %d",calculated,GetLastError());
return(0);
}
//--- bu, gösterge değerlerinin ilk hesaplanması ise veya iIchimoku göstergesinin değerleri değiştiyse
//--- veya göstergeyi iki veya daha fazla çubuk için hesaplamak gerekiyorsa (yani fiyat geçmişi değiştiyse)
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- verilen sembol ve periyot için Tenkan_sen_Buffer dizisinin büyüklüğü iIchimoku göstergesinin değerlerinden fazlaysa, her şeyi kopyalamayacağız
//--- Aksi durumda, gösterge tamponlarının büyüklüklerinden daha az kopyalama yaparız
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- Bu, gösterge değerlerinin daha önce hesaplandığı anlamına geliyor OnCalculate() fonksiyonu daha önce çağrılmış)
//--- hesaplama için bir çubuktan fazlası eklenmeyecek
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- dizileri Ichimoku Kinko Hyo indicator göstergesinin değerleriyle doldur
//--- FillArraysFromBuffer fonksiyonu false dönüşü yaparsa, bilgi henüz kullanılabilir değildir, çık
if(!FillArraysFromBuffers(Tenkan_sen_Buffer,Kijun_sen_Buffer,Senkou_Span_A_Buffer,Senkou_Span_B_Buffer,Chinkou_Span_Buffer,
kijun_sen,handle,values_to_copy)) return(0);
//--- mesajı oluştur
string comm=StringFormat("%s ==> göstergedeki gncellenen değer %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- servis mesajını çizelgede göster
Comment(comm);
//--- Ichimoku Kinko Hyo göstergesindeki değerlerin sayısını koruyacağız
bars_calculated=calculated;
//--- bir sonraki çağrı için prev_calculated değerine dönüş yap
return(rates_total);
}
//+------------------------------------------------------------------+
//| iIchimoku göstergesi ile, gösterge tamponlarının doldurulması |
//+------------------------------------------------------------------+
bool FillArraysFromBuffers(double &tenkan_sen_buffer[], // Tenkan-sen çizgisi için gösterge tamponu
double &kijun_sen_buffer[], // Kijun_sen çizgisi için gösterge tamponu
double &senkou_span_A_buffer[], // Senkou Span A çizgisi için gösterge çizgisi
double &senkou_span_B_buffer[], // Senkou Span B çizgisi için gösterge çizgisi
double &chinkou_span_buffer[], // Chinkou Span çizgisi için gösterge çizgisi
int senkou_span_shift, // Senkou Span çizgileri için ileriye dönük kaydırma çizgileri
int ind_handle, // iIchimoku göstergesinin tanıtıcı değeri
int amount // kopyalanan değerlerin sayısı
)
{
//--- hata kodunu sıfırla
ResetLastError();
//--- Tenkan_sen_Buffer dizisinin bir kısmını 0 indisli tamponun değerleriyle doldur
if(CopyBuffer(ind_handle,0,0,amount,tenkan_sen_buffer)<0)
{
//--- kopyalama başarısız ise hata kodu al
PrintFormat("1. iIchimoku göstergesinin verileri kopyalanamadı, hata kodu %d",GetLastError());
//--- sıfır sonuç ile çık - gösterge hesaplanmamış sayılacak
return(false);
}
//--- Kijun_sen_Buffer dizisinin bir kısmını 1 indisli tamponun değerleriyle doldur
if(CopyBuffer(ind_handle,1,0,amount,kijun_sen_buffer)<0)
{
//--- kopyalama başarısız ise hata kodu al
PrintFormat("2. iIchimoku göstergesinin verileri kopyalanamadı, hata kodu %d",GetLastError());
//--- sıfır sonuç ile çık - gösterge hesaplanmamış sayılacak
return(false);
}
//--- Chinkou_Span_Buffer dizisinin bir kısmını 2 indisli tamponun değerleriyle doldur
//--- senkou_span_shift>0 ise, tçizgi ileriye doğru senkou_span_shift çubuk kadar kaydırılır
if(CopyBuffer(ind_handle,2,-senkou_span_shift,amount,senkou_span_A_buffer)<0)
{
//--- kopyalama başarısız ise hata kodu al
PrintFormat("3. iIchimoku göstergesinin verileri kopyalanamadı, hata kodu %d",GetLastError());
//--- sıfır sonuç ile çık - gösterge hesaplanmamış sayılacak
return(false);
}
//--- Senkou_Span_A_Buffer dizisinin bir kısmını 3 indisli tamponun değerleriyle doldur
//--- senkou_span_shift>0 ise, tçizgi ileriye doğru senkou_span_shift çubuk kadar kaydırılır
if(CopyBuffer(ind_handle,3,-senkou_span_shift,amount,senkou_span_B_buffer)<0)
{
//--- kopyalama başarısız ise hata kodu al
PrintFormat("4. iIchimoku göstergesinin verileri kopyalanamadı, hata kodu %d",GetLastError());
//--- sıfır sonuç ile çık - gösterge hesaplanmamış sayılacak
return(false);
}
//--- Senkou_Span_B_Buffer dizisinin bir kısmını 0 indisli tamponun değerleriyle doldur
//--- Chinkou Span değerlerini kopyalarken, Chinkou Span verisi zaten bir kaydırma değeri ile kaydedildiğinden
//--- Chinkou Span çizgisine bir kaydırma değeri ayarlanması gerekmiyor
if(CopyBuffer(ind_handle,4,0,amount,chinkou_span_buffer)<0)
{
//--- kopyalama başarısız ise hata kodu al
PrintFormat("5. iIchimoku göstergesinin verileri kopyalanamadı, hata kodu %d",GetLastError());
//--- sıfır sonuç ile çık - gösterge hesaplanmamış sayılacak
return(false);
}
//--- herşey yolunda
return(true);
}
//+------------------------------------------------------------------+
//| Indicator deinitialization function |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- göstergeyi sildikten sonra çizelgeyi temizle
Comment("");
}
|