DocumentaçãoSeções
Referência MQL5Funções de StringStringSplit 

StringSplit

Obtém substrings por meio um separador especificado a partir de uma string especificada, retorna o número de substrings obtidas.

int  StringSplit(
   const string   string_value,       // A string que será pesquisada
   const ushort   separator,          // Um separador usado para buscar substrings
   string         & result[]          // Um array passado por referencia para obter as substrings encontradas
   );

Parâmetros

string_value

[in]  Uma string da qual você necessita obter substrings. A string não será alterada.

pos

[in]  O código do caractere separador. Para obter o código, você pode usar a função StringGetCharacter().

result[]

[out]  Um array de strings onde as substrings obtidas estão localizadas.

Valor do Retorno

O número de substrings no array result[]. Se o separador não for encontrado na string passada, somente uma string fonte será colocada no array.

Se string_value for vazia ou NULL, a função retornará zero. No caso de um erro, a função retorna -1. Para obter o código do erro, chame a função GetLastError().

Exemplo:

string to_split="_life_is_good_"; // Um string para dividir em substrings
   string sep="_";                // Um separador como um caractere
   ushort u_sep;                  // O código do caractere separador
   string result[];               // Um array para obter strings
   //--- Obtém o código do separador
   u_sep=StringGetCharacter(sep,0);
   //--- Divide a string em substrings
   int k=StringSplit(to_split,u_sep,result);
   //--- Exibe um comentário
   PrintFormat("Strings obtidos: %d. Usado separador '%s' com o código %d",k,sep,u_sep);
   //--- Agora imprime todos os resultados obtidos
   if(k>0)
     {
      for(int i=0;i<k;i++)
        {
         PrintFormat("result[%d]=\"%s\"",i,result[i]);
        }
     }

Também Veja

StringReplace(), StringSubstr(), StringConcatenate()