//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- código do país para a Alemanha de acordo com a ISO 3166-1 Alpha-2
string germany_code="DE";
//--- obtenha os eventos para a Alemanha
MqlCalendarEvent events[];
int events_count=CalendarEventByCountry(germany_code,events);
//--- imprima os eventos para a Alemanha no Diário
if(events_count>0)
{
PrintFormat("Eventos para a Alemanha: %d",events_count);
ArrayPrint(events);
}
else
{
PrintFormat("Falha ao obter eventos para o código do país %s, erro %d",
germany_code,GetLastError());
//--- conclusão antecipada do script
return;
}
//--- obtenha a descrição do último evento do array events[]
MqlCalendarEvent event;
ulong event_id=events[events_count-1].id;
if(CalendarEventById(event_id,event))
{
MqlCalendarCountry country;
CalendarCountryById(event.country_id,country);
PrintFormat("Obtida a descrição do evento com event_id=%d",event_id);
PrintFormat("País: %s (código do país= %d)",country.name,event.country_id);
PrintFormat("Nome do evento: %s",event.name);
PrintFormat("Código do evento: %s",event.event_code);
PrintFormat("Importância do evento: %s",EnumToString((ENUM_CALENDAR_EVENT_IMPORTANCE)event.importance));
PrintFormat("Tipo de evento: %s",EnumToString((ENUM_CALENDAR_EVENT_TYPE)event.type));
PrintFormat("Setor do evento: %s",EnumToString((ENUM_CALENDAR_EVENT_SECTOR)event.sector));
PrintFormat("Frequência do evento: %s",EnumToString((ENUM_CALENDAR_EVENT_FREQUENCY)event.frequency));
PrintFormat("Modo de saída do evento: %s",EnumToString((ENUM_CALENDAR_EVENT_TIMEMODE)event.time_mode));
PrintFormat("Unidade de medida do evento: %s",EnumToString((ENUM_CALENDAR_EVENT_UNIT)event.unit));
PrintFormat("Número de casas decimais: %d",event.digits);
PrintFormat("Multiplicador de valor: %s",EnumToString((ENUM_CALENDAR_EVENT_MULTIPLIER)event.multiplier));
PrintFormat("URL da fonte: %s",event.source_url);
}
else
PrintFormat("Falha ao obter a descrição do evento para event_d=%s, erro %d",
event_id,GetLastError());
}
/*
Resultado:
Eventos para a Alemanha: 50
[id] [type] [sector] [frequency] [time_mode] [country_id] [unit] [importance] [multiplier] [digits] [source_url] [event_code] [name] [reserved]
[ 0] 276010001 1 6 2 0 276 1 1 0 1 "https://www.destatis.de/EN/Homepage.html" "exports-mm" "Exports m/m" 0
[ 1] 276010002 1 6 2 0 276 1 1 0 1 "https://www.destatis.de/EN/Homepage.html" "imports-mm" "Imports m/m" 0
[ 2] 276010003 1 4 2 0 276 1 1 0 1 "https://www.destatis.de/EN/Homepage.html" "import-price-index-mm" "Import Price Index m/m" 0
[ 3] 276010004 1 4 2 0 276 1 1 0 1 "https://www.destatis.de/EN/Homepage.html" "import-price-index-yy" "Import Price Index y/y" 0
....
[47] 276500001 1 8 2 0 276 0 2 0 1 "https://www.markiteconomics.com" "markit-manufacturing-pmi" "Markit Manufacturing PMI" 0
[48] 276500002 1 8 2 0 276 0 2 0 1 "https://www.markiteconomics.com" "markit-services-pmi" "Markit Services PMI" 0
[49] 276500003 1 8 2 0 276 0 2 0 1 "https://www.markiteconomics.com" "markit-composite-pmi" "Markit Composite PMI" 0
Descrições de evento recebidas com event_id=276500003
País: Germany (código do país = 276)
Nome do evento: Markit Composite PMI
Código do evento: markit-composite-pmi
Importância do evento: CALENDAR_IMPORTANCE_MODERATE
Tipo de evento: CALENDAR_TYPE_INDICATOR
Setor do evento: CALENDAR_SECTOR_BUSINESS
Frequência do evento: CALENDAR_FREQUENCY_MONTH
Modo de saída do evento: CALENDAR_TIMEMODE_DATETIME
Unidade de medida do evento: CALENDAR_UNIT_NONE
Número de casas decimais: 1
Multiplicador de valor: CALENDAR_MULTIPLIER_NONE
URL da fonte: https://www.markiteconomics.com
*/
|