CDouble & CDoubleVector - biblioteca para MetaTrader 5

Uma biblioteca para métodos de arredondamento comuns usados no desenvolvimento MQL, classe wrapper primitiva para "type" (double) e vetor para objetos CDouble. MQL5 e MQL4 são compatíveis!

CDouble

A classe CDouble envolve um valor do tipo primitivo double em um objeto. Além disso, essa classe fornece vários métodos e métodos estáticos para arredondar doubles e arrays/collections do tipo double.

Declaração

class CDouble : public CObject

Título

#include <Double.mqh>

Hierarquia de herança

• CObject
  • CDouble

Método Virtual implementado/substituído pela classe CObject: Type, Load, Save, Compare.

Um objeto do tipo CDouble contém cinco campos de dados:

string

m_symbol

double

m_value

uchar

m_step

uchar

m_digits

ENUM_PRECISION

m_mode

Antes de nos aprofundarmos mais nos documentos, aqui está um rápido exemplo prático da classe wrapper em ação:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   CDouble  price = tick.ask - 0.0087263487676283476,
            sl    = price - 500*_Point,
            tp    = price + 500*_Point,
            lots  = 5.25 / 3.78789;
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = price.AsRoundedTick();
   r.sl    = sl.AsRoundedTick();
   r.tp    = tp.AsRoundedTick();
   r.volume= lots.AsRoundedLots();
...

Outro exemplo usando os métodos estáticos da biblioteca:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = tick.ask - 0.0087263487676283476,
   r.sl    = price - 500*_Point,
   r.tp    = price + 500*_Point,
   r.volume= 5.25 / 3.78789;
   ...
   CDouble::RoundTradeRequest(r);
   //Arredonda automaticamente os campos de preço para o tamanho do tick
   //e o volume para step do lote

Resumo do método estático

Nota: Não é necessário saber OOP ou usar uma instância da classe wrapper para fazer uso desta biblioteca. Tudo o que tem a fazer é chamar as funções estáticas com a resolução de escopo do CDouble. A sintaxe é a seguinte:

type variable_name = CDouble::Method(args);

static bool

IsEqual
(double number1,
 double number2,
 double step);

static bool

IsEqual
(double number1,
 double number2,
 int digits);

static int

Compare
(double number1,
 double number2,
 double step)

static double

RoundToStep
(const double number, 
 double step)

static double

RoundToDigit
(const double number, 
 int digits)

static double

RoundToStepUp
(const double number, 
 double step)

static double

RoundToStepDown
(const double number, 
 double step)

static double

RoundToTick
(const double number, 
 string symbol=NULL)

static double

RoundToLots
(const double number,
 string symbol=NULL,
 bool always_return_valid=true)

static void (MQL5)

RoundTradeRequest
(MqlTradeRequest &request)

static void

RoundArrayToStep
(double &arr[],
 double step = NULL)

static void

RoundArrayToStep
(CArrayDouble &arr,
 double step = NULL)

static int

GetDigits
(double floating_point)

static double 

GetPoint
(int digits)

static string

ToString
(double number,
 int digits)

Exemplos:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   double rnd_by_step   = CDouble::RoundToStep(tick.bid*1.052565465,_Point);
   double rnd_by_digits = CDouble::RoundToDigit(tick.bid*1.052565465,_Digits);
   double by_lot_step   = CDouble::RoundToLots(0.123423,_Symbol);
   double by_tick_size  = CDouble::RoundToTick(tick.ask-100*_Point,_Symbol);
   double roundup       = CDouble::RoundToStepUp(3.999999999,_Point);
   double rounddn       = CDouble::RoundToStepDown(3.999999999,_Point);
   int    digits        = CDouble::GetDigits(0.0000025);
   double point         = CDouble::GetPoint(10);
   bool   equal         = CDouble::IsEqual(tick.bid,tick.bid+0.00000009,_Point);
   string tostr         = CDouble::ToString(3.1399999999999999);
   int    compare       = CDouble::Compare(tick.ask,tick.bid);
   
#ifdef __MQL5__
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = tick.ask+0.000089849847658759198199999;
   r.sl    = r.price - 503 * _Point;
   r.tp    = r.price + 503 * _Point;
   r.volume= 1.127984984;
   
   CDouble::RoundTradeRequest(r);
#endif 

Resumo do Construtor

CDouble
(const ENUM_PRECISION mode = PRECISION_DEFAULT,
 const string symbol = NULL)

CDouble
(const CDouble &other)

Exemplos:

CDouble num;
CDouble bid(PRECISION_TICK_SIZE, _Symbol);
CDouble ask(bid)
CDouble ask2 = bid;
CDouble lots(PRECISION_LOT_STEP, _Symbol);

Resumo de Atribuição - Operadores de Atribuição de Sobrecarga

void

Set(const double value)

void

Set(const CDouble &other)

void

Nota: o operador de atribuição = pode ser chamado na mesma linha como declaração.

Exemplos:

CDouble bid;
bid.Set(tick.bid);
CDouble ask = tick.ask;

CDouble pi = 3.14;
CDouble factor = 2;
pi*=factor;
Print(pi.ToString());
//6.28

Resumo do Operador Aritmético de Sobrecarga

double

Nota: Apenas um operador aritmético pode ser usado pela declaração.

Sintaxe para a aritmética do operador de sobrecarga:

type_double_result <-- CDouble_object <-- operator <-- double
//objeto CDouble sempre vai estar no lado esquerdo do operador

type_double_result <-- CDouble_object1 <-- operator <-- CDouble_object2
//a ordem não importa quando usa dois objetos CDouble.

Exemplos:

CDouble foo    = 3.14;
CDouble bar    = 10;
CDouble foobar = bar + foo;          //13.14
CDouble err    = bar + foo + foobar; //erro - operação ilegal usada

double var = bar / foo;

Resumo do Operador de Comparação de Sobrecarga

bool

Exemplos:

CDouble foo = 3.14, bar = 3.139999999999999999999;
   
   Print(foo == bar); //verdadeiro
   Print(foo <= bar); //verdadeiro
   Print(foo >  bar); //falso

Resumo do Método de Instância

Controle de Precisão (padrão): digits = 8; step = 1e-08

• Existem três maneiras de controlar a precisão:: Step, Digits, ou PrecisionMode(ENUM_PRECISION). Qualquer chamada para qualquer um desses métodos setter substituirá as configurações anteriores.
• O Step é o _Point, ou o LOT_STEP, ou ainda, o TickSize; representado como um ponto flutuante (por exemplo 0.00001, 0.025, etc.)
• Não é necessário definir o Step, pois RoundToTick e RoundToLot usam automaticamente os valores de Step apropriados para o retorno do arredondamento.

void

PrecisionMode
(const ENUM_PRECISION mode)

ENUM_PRECISION

PrecisionMode()

void

Step
(const double step_or_point)

double

Step()

void

Digits
(const int digits)

int

Digits()

double

AsRawDouble()

double

AsRounded()

double

AsRoundedUp()

double

AsRoundedDown()

double

AsRoundedTick()

double

AsRoundedLots
(bool always_return_valid = true)

int

ToInt()

long

ToLong()

string

ToStringPrecision()

string

ToString()

string

Symbol()

string

Symbol(const string symbol)

Exemplos:

CDouble pi2 = 3.14159265359;
   
   // obter valor como... 
   double raw_double             = pi2.AsRawDouble();
   double round_double_to_step   = pi2.AsRounded();
   double tick_size_double       = pi2.AsRoundedTick();
   double lot_step_double        = pi2.AsRoundedLots();
   double rounded_up             = pi2.AsRoundedUp();
   double rounded_down           = pi2.AsRoundedDown();
   int    double_to_int          = pi2.ToInt();
   long   double_to_long         = pi2.ToLong();
   string precision_str          = pi2.ToStringPrecision();
   pi2 = 3.140000000009;
   pi2.Digits(8);
   string truncated_str          = pi2.ToString();

Resumo do método de instância

Métodos substituídos do CObject:

virtual int

Compare
(const CObject *node,
 const int mode=0)

virtual int

Type()

virtual bool

Save(const int file_handle)

virtual bool

Load(const int file_handle)

Como exemplo, veja a classe CDoubleVector a seguir.

CDoubleVector

A classe CDoubleVector é uma coleção especializada de ponteiro de objeto para instâncias dinâmicas CDouble.

Declaração

class CDoubleVector : public CArrayObj

Título

#include <Double.mqh>

Hierarquia de herança

• CObject
  • CArray
    • CArrayObj
      • CDoubleVector

Virtual Methods implemented/overridden from class CArrayObj: CreateElement.

Resumo do Método de Instância

**Ver métodos herdados da classe CArrayObj.

CDouble*

operator[]
(const int index)

bool

Add(const double value)

bool

AssignDoubleArray
(const double &array[])

bool

CopyOut(double &arr[])

bool

CopyOut(CArrayDouble &arr)

virtual bool

Save(const int file_handle)

virtual bool

Load(const int file_handle)

Exemplos:

CDoubleVector *vect = new CDoubleVector;
   
   double dubs[]={3.14,1.21,55.555};
   vect.AssignDoubleArray(dubs);
   vect.Add(tick.bid);
   
   //chamando o objeto CDouble pelo índice
   Print(vect[vect.Total()-1].ToString());
   
   //adicionar um novo objeto CDouble 
   CDouble *lot = new CDouble(PRECISION_LOT_STEP);
   lot = 1.22;
   vect.Add(lot);
   
   //vetor de classificação ascendente
   vect.Sort();
   
   int total = vect.Total();
   
   //salva vetor para arquivo, incluindo estados e valores do objeto CDouble
   string f = "testdub.bin";
   int    h = FileOpen(f,FILE_WRITE|FILE_BIN);
   if(vect.Save(h))
      Print("save successful");
   FileClose(h);
   delete vect;
   
   //salva vetor a partir do arquivo
   CDoubleVector vect_reborn;
   h=FileOpen(f,FILE_READ|FILE_BIN);
   if(vect_reborn.Load(h))
      Print("load successful");
   FileClose(h);
   total = vect_reborn.Total();
   Print("Total vector size = ",sizeof(vect_reborn)," bytes");
   for(int i=0;i<vect_reborn.Total();i++)
      Print(vect_reborn[i].ToString());
      
   //copiar para double arr
   double arr2[];
   vect_reborn.CopyOut(arr2);
   Print(ArraySize(arr2));