TextOut

bool  TextOut(
   const string       text,          // 표시된 텍스트
   int                x,             // X 좌표 
   int                y,             // Y 좌표 
   uint               anchor,        // 앵커 유형
   uint               &data[],       // 출력 버퍼
   uint               width,         // 버퍼 너비(픽셀)
   uint               height,        // 버퍼 높이(픽셀)
   uint               color,         // 텍스트 색상
   ENUM_COLOR_FORMAT  color_format   // 출력용 색상 형식
   );

//--- 너비와 캔버스(그리기에 사용되는)의 높이.
#define IMG_WIDTH  200
#define IMG_HEIGHT 200
//--- 스크립트를 시작하기 전에 매개 변수 창을 표시합니다
#property script_show_inputs
//--- 색상 형식을 설정합니다
input ENUM_COLOR_FORMAT clr_format=COLOR_FORMAT_XRGB_NOALPHA;
//--- 그리기 배열(버퍼)
uint ExtImg[IMG_WIDTH*IMG_HEIGHT];
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 그리기를 위해 OBJ_BITMAP_LABEL 개체 생성    
   ObjectCreate(0,"CLOCK",OBJ_BITMAP_LABEL,0,0,0);
//--- CLOCK 객체에 쓸 그래픽 리소스의 이름을 명시합니다
   ObjectSetString(0,"CLOCK",OBJPROP_BMPFILE,"::IMG");
 
//--- auxiliary variables
   double a;            // 애로우 코너
   uint   nm=2700;      // 분(minute) 코너
   uint   nh=2700*12;   // 시간(hour) 카운터
   uint   w,h;          // 텍스트 문자열 크기를 수신하기 위한 변수 
   int    x,y;          // 텍스트 문자열 앵커 지점의 현재 좌표를 계산하기 위한 변수
 
//--- 스크립트가 중지될 때까지 시계 바늘을 무한 루프에서 회전합니다
   while(!IsStopped())
     {
      //--- 시계 그리기 버퍼 배열을 지웁니다
      ArrayFill(ExtImg,0,IMG_WIDTH*IMG_HEIGHT,0);
      //--- 시계 페이스 숫자 그리기 글꼴 설정
      TextSetFont("Arial",-200,FW_EXTRABOLD,0);
      //--- 시계 페이스 그리기
      for(int i=1;i<=12;i++)
        {
         //--- 시계 페이스의 현재 시간에 대한 크기를 받음
         TextGetSize(string(i),w,h);
         //--- 시계 페이스의 현재 시간 좌표를 계산
         a=-((i*300)%3600*M_PI)/1800.0;
         x=IMG_WIDTH/2-int(sin(a)*80+0.5+w/2);
         y=IMG_HEIGHT/2-int(cos(a)*80+0.5+h/2);
         //--- 시계 페이스의 시간을 ExtImg[] 버퍼로 출력
         TextOut(string(i),x,y,TA_LEFT|TA_TOP,ExtImg,IMG_WIDTH,IMG_HEIGHT,0xFFFFFFFF,clr_format);
        }
      //--- 이제, 분침을 그릴 글꼴을 지정합니다      
      TextSetFont("Arial",-200,FW_EXTRABOLD,-int(nm%3600));
      //--- 분침의 크기를 받습니다
      TextGetSize("----->",w,h);
      //--- 시계 페이스의 분침의 좌표를 계산
      a=-(nm%3600*M_PI)/1800.0;
      x=IMG_WIDTH/2-int(sin(a)*h/2+0.5);
      y=IMG_HEIGHT/2-int(cos(a)*h/2+0.5);
      //--- ExtImg[] 버퍼의 시계 페이스 분침 출력
      TextOut("----->",x,y,TA_LEFT|TA_TOP,ExtImg,IMG_WIDTH,IMG_HEIGHT,0xFFFFFFFF,clr_format);
 
      //--- 자, 분침을 그릴 폰트를 설정하세요      
      TextSetFont("Arial",-200,FW_EXTRABOLD,-int(nh/12%3600));
      TextGetSize("==>",w,h);
      //--- 시계 페이스의 시침의 좌표를 계산
      a=-(nh/12%3600*M_PI)/1800.0;
      x=IMG_WIDTH/2-int(sin(a)*h/2+0.5);
      y=IMG_HEIGHT/2-int(cos(a)*h/2+0.5);
      //--- ExtImg[] 버퍼에 대한 시계 페이스의 시침 출력
      TextOut("==>",x,y,TA_LEFT|TA_TOP,ExtImg,IMG_WIDTH,IMG_HEIGHT,0xFFFFFFFF,clr_format);
 
      //--- update the graphical resource
      ResourceCreate("::IMG",ExtImg,IMG_WIDTH,IMG_HEIGHT,0,0,IMG_WIDTH,clr_format);
      //--- 포스 차트 업데이트
      ChartRedraw();
 
      //--- 시간 및 분 카운터 증가
      nm+=60;
      nh+=60;
      //--- 프레임 사이에 잠시 멈춤
      Sleep(10);
     }
//--- 스크립트 작업을 완료할 때 CLOCK 개체 삭제
   ObjectDelete(0,"CLOCK");
//---
  }