//--- 설명
#property description "스크립트가 차트에 버튼을 생성합니다."
//--- 스크립트 실행 중 입력 매개변수의 표시 창
#property script_show_inputs
//--- 스크립트의 입력 매개변수
input string InpName="Button"; // 버튼 이름
input ENUM_BASE_CORNER InpCorner=CORNER_LEFT_UPPER; // 고정하기 위한 차트 모서리
input string InpFont="Arial"; // 글꼴
input int InpFontSize=14; // 글꼴 크기
input color InpColor=clrBlack; // 텍스트 색상
input color InpBackColor=C'236,233,216'; // 배경 색상
input color InpBorderColor=clrNONE; // 테두리 색상
input bool InpState=false; // 누름/해제
input bool InpBack=false; // 배경 개체
input bool InpSelection=false; // 이동하려면 강조 표시
input bool InpHidden=true; // 개체 목록에 숨겨짐
input long InpZOrder=0; // 마우스 클릭 우선 순위
//+------------------------------------------------------------------+
//| 버튼 생성 |
//+------------------------------------------------------------------+
bool ButtonCreate(const long chart_ID=0, // 차트의 ID
const string name="Button", // 버튼 이름
const int sub_window=0, // 하위 창 인덱스
const int x=0, // X 좌표
const int y=0, // Y 좌표
const int width=50, // 버튼 너비
const int height=18, // 버튼 높이
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER, // 고정하기 위한 차트 모서리
const string text="Button", // 텍스트
const string font="Arial", // 글꼴
const int font_size=10, // 글꼴 크기
const color clr=clrBlack, // 텍스트 색상
const color back_clr=C'236,233,216', // 배경 색상
const color border_clr=clrNONE, // 테두리 색상
const bool state=false, // 누름/해제
const bool back=false, // 배경에
const bool selection=false, // 이동하려면 강조 표시
const bool hidden=true, // 개체 목록에 숨겨짐
const long z_order=0) // 마우스 클릭 우선 순위
{
//--- 오류 값 재설정
ResetLastError();
//--- 버튼 생성
if(!ObjectCreate(chart_ID,name,OBJ_BUTTON,sub_window,0,0))
{
Print(__FUNCTION__,
": 버튼 생성 실패! Error code = ",GetLastError());
return(false);
}
//--- 버튼 좌표 설정
ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x);
ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y);
//--- 버튼 크기 설정
ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width);
ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height);
//--- 지정된 점 좌표를 기준으로 차트 모서리 설정
ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner);
//--- 텍스트 설정
ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);
//--- 텍스트 글꼴 설정
ObjectSetString(chart_ID,name,OBJPROP_FONT,font);
//--- 글꼴 크기 설정
ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size);
//--- 텍스트 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 배경 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_BGCOLOR,back_clr);
//--- 테두리 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_BORDER_COLOR,border_clr);
//--- 전경(false) 또는 배경(true)에 표시
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 버튼 상태 설정
ObjectSetInteger(chart_ID,name,OBJPROP_STATE,state);
//--- 마우스로 버튼 이동 모드 활성화(true) 또는 비활성화(false)
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 개체 목록에서 그래픽 개체 이름 숨기기(true) 또는 표시(false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 차트에서 마우스 클릭 이벤트 수신 우선 순위 설정
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 버튼 이동 |
//+------------------------------------------------------------------+
bool ButtonMove(const long chart_ID=0, // 차트의 ID
const string name="Button", // 버튼 이름
const int x=0, // X 좌표
const int y=0) // Y 좌표
{
//--- 오류 값 재설정
ResetLastError();
//--- 버튼 이동
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x))
{
Print(__FUNCTION__,
": 버튼의 X 좌표 이동 실패! Error code = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y))
{
Print(__FUNCTION__,
": 버튼의 Y 좌표 이동 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| Change button size |
//+------------------------------------------------------------------+
bool ButtonChangeSize(const long chart_ID=0, // 차트의 ID
const string name="Button", // 버튼 이름
const int width=50, // 버튼 너비
const int height=18) // 버튼 높이
{
//--- 오류 값 재설정
ResetLastError();
//--- 버튼 크기 변경
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width))
{
Print(__FUNCTION__,
": 버튼 너비 변경 실패! Error code = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height))
{
Print(__FUNCTION__,
": 버튼 높이 변경 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 버튼 바인딩에 대한 차트의 모서리 변경 |
//+------------------------------------------------------------------+
bool ButtonChangeCorner(const long chart_ID=0, // 차트의 ID
const string name="Button", // 버튼 이름
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER) // 고정을 위한 차트의 모서리
{
//--- 오류 값 재설정
ResetLastError();
//--- 고정 모서리 변경
if(!ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner))
{
Print(__FUNCTION__,
": 고정 모서리 변경 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 버튼 텍스트 변경 |
//+------------------------------------------------------------------+
bool ButtonTextChange(const long chart_ID=0, // 차트의 ID
const string name="Button", // 버튼 이름
const string text="Text") // 텍스트
{
//--- 오류 값 재설정
ResetLastError();
//--- 개체 텍스트 변경
if(!ObjectSetString(chart_ID,name,OBJPROP_TEXT,text))
{
Print(__FUNCTION__,
": 텍스트 변경 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 버튼 삭제 |
//+------------------------------------------------------------------+
bool ButtonDelete(const long chart_ID=0, // 차트의 ID
const string name="Button") // 버튼 이름
{
//--- 오류 값 재설정
ResetLastError();
//--- 버튼 삭제
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": 버튼 삭제 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 차트 창 크기
long x_distance;
long y_distance;
//--- 창 크기 설정
if(!ChartGetInteger(0,CHART_WIDTH_IN_PIXELS,0,x_distance))
{
Print("차트 너비 가져오기 실패! Error code = ",GetLastError());
return;
}
if(!ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,0,y_distance))
{
Print("차트 높이 가져오기 실패! Error code = ",GetLastError());
return;
}
//--- 버튼 크기 변경 단계 지정
int x_step=(int)x_distance/32;
int y_step=(int)y_distance/32;
//--- 버튼 좌표 및 크기 설정
int x=(int)x_distance/32;
int y=(int)y_distance/32;
int x_size=(int)x_distance*15/16;
int y_size=(int)y_distance*15/16;
//--- 버튼 생성
if(!ButtonCreate(0,InpName,0,x,y,x_size,y_size,InpCorner,"Press",InpFont,InpFontSize,
InpColor,InpBackColor,InpBorderColor,InpState,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- 차트 다시 그리기
ChartRedraw();
//--- 루프의 버튼 줄이기
int i=0;
while(i<13)
{
//--- 0.5 초 지연
Sleep(500);
//--- 버튼을 누름 상태로 전환
ObjectSetInteger(0,InpName,OBJPROP_STATE,true);
//--- 차트를 다시 그리고 0.2초 동안 대기
ChartRedraw();
Sleep(200);
//--- 좌표 및 버튼 크기 재지정
x+=x_step;
y+=y_step;
x_size-=x_step*2;
y_size-=y_step*2;
//--- 버튼 줄이기
ButtonMove(0,InpName,x,y);
ButtonChangeSize(0,InpName,x_size,y_size);
//--- 버튼을 해제된 상태로 되돌림
ObjectSetInteger(0,InpName,OBJPROP_STATE,false);
//--- 차트 다시 그리기
ChartRedraw();
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 루프 카운터를 증가
i++;
}
//--- 0.5초 지연
Sleep(500);
//--- 버튼 삭제
ButtonDelete(0,InpName);
ChartRedraw();
//--- 1초 동안 대기
Sleep(1000);
//---
}
|