Operaciones matemáticas sobre matrices y vectores
Las operaciones matemáticas (suma, resta, multiplicación y división) se pueden realizar en matrices y vectores miembro a miembro.
Las funciones matemáticas se diseñaron originalmente para realizar operaciones matemáticas en valores escalares. Ahora, la mayoría de estas funciones también se pueden usar con los nuevos tipos de datos matrices y vectores MathAbs, MathArccos, MathArcsin, MathArctan, MathCeil, MathCos, MathExp, MathFloor, MathLog, MathLog10, MathMod, MathPow, MathRound, MathSin, MathSqrt, MathTan, MathExpm1, MathLog1p, MathArccosh, MathArcsinh, MathArctanh, MathCosh, MathSinh, MathTanh. En este caso, la matriz o vector se procesa por miembros. Ejemplo:
//---
matrix a= {{1, 4}, {9, 16}};
Print("matrix a=\n",a);
a=MathSqrt(a);
Print("MatrSqrt(a)=\n",a);
/*
matrix a=
[[1,4]
[9,16]]
MatrSqrt(a)=
[[1,2]
[3,4]]
*/
|
En el caso de MathMod y MathPow, como segundo parámetro, podremos usar tanto un escalar como una matriz o vector del tamaño correspondiente
Vamos a ver un ejemplo en el que mostraremos cómo calcular la desviación estándar usando funciones matemáticas sobre un vector.
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- usamos una función de inicialización para rellenar el vector
vector r(10, ArrayRandom); // matriz de números aleatorios de 0 a 1
//--- calculamos el valor medio
double avr=r.Mean(); // valor medio del array
vector d=r-avr; // calculamos el array de desviaciones respecto al valor medio
Print("avr(r)=", avr);
Print("r=", r);
Print("d=", d);
vector s2=MathPow(d, 2); // array de cuadrados de las desviaciones
double sum=s2.Sum(); // suma de los cuadrados de las desviaciones
//--- calcularemos la desviación estándar de 2 maneras
double std=MathSqrt(sum/r.Size());
Print(" std(r)=", std);
Print("r.Std()=", r.Std());
}
/*
avr(r)=0.5300302133243813
r=[0.8346201971495713,0.8031556138798182,0.6696676534318063,0.05386516922513505,0.5491195410016175,0.8224433118686484,...
d=[0.30458998382519,0.2731254005554369,0.1396374401074251,-0.4761650440992462,0.01908932767723626,0.2924130985442671, ...
std(r)=0.2838269732183663
r.Std()=0.2838269732183663
*/
//+------------------------------------------------------------------+
//| Rellena el vector con valores aleatorios |
//+------------------------------------------------------------------+
void ArrayRandom(vector& v)
{
for(ulong i=0; i<v.Size(); i++)
v[i]=double(MathRand())/32767.;
}
|