iGator

Devuelve el manejador del indicador Gator. El oscilador muestra la diferencia entre la línea azul y roja del Aligátor (histograma de arriba) y la diferencia entre la línea roja y verde (histograma de abajo).

int  iGator(
   string              symbol,            // nombre del símbolo
   ENUM_TIMEFRAMES     period,            // período
   int                 jaw_period,        // período para el cálculo de mandíbulas
   int                 jaw_shift,         // desplazamiento horizontal de mandíbulas
   int                 teeth_period,      // período para el cálculo de dientes
   int                 teeth_shift,       // desplazamiento horizontal de dientes
   int                 lips_period,       // período para el cálculo de labios
   int                 lips_shift,        // desplazamiento horizontal de labios 
   ENUM_MA_METHOD      ma_method,         // tipo de suavizado
   ENUM_APPLIED_PRICE  applied_price      // tipo de precio o manejador
   );

Parámetros

symbol

[in]  Símbolo del instrumento financiero cuyos datos serán usados para calcular el indicador. NULL significa el símbolo actual.

period

[in]  Valor del período puede ser uno de los valores de la enumeración ENUM_TIMEFRAMES, 0 significa el timeframe actual.

jaw_period

[in]  Período promedio para la línea azul (mandíbulas de aligátor).

jaw_shift

[in]  Desplazamiento de la línea azul del Aligátor con relación al gráfico de precios. No tiene relación directa con el desplazamiento visual del histograma del indicador.

teeth_period

[in]  Período promedio para la línea roja (dientes de aligátor).

teeth_shift

[in]  Desplazamiento de la línea roja del Aligátor con relación al gráfico de precios. No tiene relación directa con el desplazamiento visual del histograma del indicador.

lips_period

[in]  Período promedio para la línea verde (labios de aligátor).

lips_shift

[in]  Desplazamiento de la línea verde del Aligátor con relación al gráfico de precios. No tiene relación directa con el desplazamiento visual del histograma del indicador.

ma_method

[in]  Método de promedio. Puede ser cualquier valor de la enumeración ENUM_MA_METHOD.

applied_price

[in]  Precio que se usa. Puede ser cualquier precio de las constantes de precios ENUM_APPLIED_PRICE o un manejador de otro indicador.

Valor devuelto

Devuelve el manejador del indicador técnico especificado, en caso del fallo devuelve INVALID_HANDLE. Para liberar la memoria del ordenador del indicador que ya no se utiliza la función IndicatorRelease() a la que se le pasa el manejador (handle) de este indicador.

Nota

Números de buffers: 0 - UPPER_HISTOGRAM, 1- buffer de color del histograma de arriba, 2 - LOWER_HISTOGRAM, 3- buffer de color del histograma de abajo.

Ejemplo:

//+------------------------------------------------------------------+
//|                                                  Demo_iGator.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "El indicador demuestra cómo hay que obtener los datos"
#property description "de los búfers indicadores para el indicador técnico iGator."
#property description "El símbolo y el período de tiempo en el que se calcula el indicador"
#property description "se establecen mediante los parámetros symbol y period."
#property description "El modo de crear el manejador (handle) se establece mediante el parámetro 'type' (tipo de función)."
#property description "Todos los demás parámetros son iguales a los del Gator Oscillator estándar."
 
#property indicator_separate_window
#property indicator_buffers 4
#property indicator_plots   2
//--- construcción de GatorUp
#property indicator_label1  "GatorUp"
#property indicator_type1   DRAW_COLOR_HISTOGRAM
#property indicator_color1  clrGreen, clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- construcción de GatorDown
#property indicator_label2  "GatorDown"
#property indicator_type2   DRAW_COLOR_HISTOGRAM
#property indicator_color2  clrGreen, clrRed
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//+------------------------------------------------------------------+
//|  Enumeración de modos de crear el manejador                      |
//+------------------------------------------------------------------+
enum Creation
  {
   Call_iGator,            // usar iGator
   Call_IndicatorCreate    // usar IndicatorCreate
  };
//--- parámetros de entrada
input Creation             type=Call_iGator;       // tipo de función 
input string               symbol=" ";             // símbolo 
input ENUM_TIMEFRAMES      period=PERIOD_CURRENT;  // período de tiempo
input int                  jaw_period=13;          // período para la línea de Mandíbulas
input int                  jaw_shift=8;            // desplazamiento de la línea de Mandíbulas
input int                  teeth_period=8;         // período para la línea de Dientes
input int                  teeth_shift=5;          // desplazamiento de la línea de Dientes
input int                  lips_period=5;          // período para la línea de Labios
input int                  lips_shift=3;           // desplazamiento de la línea de Labios
input ENUM_MA_METHOD       MA_method=MODE_SMMA;    // método de promediación de las líneas del Alligator
input ENUM_APPLIED_PRICE   applied_price=PRICE_MEDIAN;// tipo del precio partiendo del cual se construye el Alligator
//--- búfers indicadores
double         GatorUpBuffer[];
double         GatorUpColors[];
double         GatorDownBuffer[];
double         GatorDownColors[];
//--- variable para guardar el manejador del indicador iGator
int    handle;
//--- variable para guardar
string name=symbol;
//--- nombre del indicador en el gráfico
string short_name;
//--- valores de desplazamiento para el histograma superior e inferior
int shift;
//--- vamos a guardar el número de los valores en el indicador Gator Oscillator
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- vinculación de los arrays a los búfers indicadores
   SetIndexBuffer(0,GatorUpBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,GatorUpColors,INDICATOR_COLOR_INDEX);
   SetIndexBuffer(2,GatorDownBuffer,INDICATOR_DATA);
   SetIndexBuffer(3,GatorDownColors,INDICATOR_COLOR_INDEX);
/*
  ¡Todos los desplazamientos especificados en los parámetros se refieren al indicador Alligator a base del que se construye Gator Oscillator!
  ¡Por esta razón dichos desplazamientos no mueven el mismo indicador Gator, sino mueven las líneas del Alligator,
  a base de cuyos valores se construyen los valores del indicador Gator Oscillator!
*/
//--- calcularemos el desplazamiento para el histograma superior e inferior que supone la diferencia entre la línea de Mandíbulas y la línea de Dientes
   shift=MathMin(jaw_shift,teeth_shift);
   PlotIndexSetInteger(0,PLOT_SHIFT,shift);
//--- a pesar de que el indicador contiene dos histogramas, se utiliza el mismo desplazamiento - así es la implementación del indicador iGator
   PlotIndexSetInteger(1,PLOT_SHIFT,shift);
 
//--- determinamos el símbolo para el que se construye el indicador
   name=symbol;
//--- eliminaremos los espacios del lado izquierdo y derecho
   StringTrimRight(name);
   StringTrimLeft(name);
//--- si después de eso la longitud de la cadena name obtiene el valor cero,
   if(StringLen(name)==0)
     {
      //--- cogeremos el símbolo del gráfico en el que está iniciado el indicador
      name=_Symbol;
     }
//--- crearemos el manejador del indicador
   if(type==Call_iGator)
      handle=iGator(name,period,jaw_period,jaw_shift,teeth_period,teeth_shift,
                    lips_period,lips_shift,MA_method,applied_price);
   else
     {
      //--- llenaremos la estructura con los valores de los parámetros del indicador
      MqlParam pars[8];
      //--- períodos y desplazamientos de las líneas del Alligator
      pars[0].type=TYPE_INT;
      pars[0].integer_value=jaw_period;
      pars[1].type=TYPE_INT;
      pars[1].integer_value=jaw_shift;
      pars[2].type=TYPE_INT;
      pars[2].integer_value=teeth_period;
      pars[3].type=TYPE_INT;
      pars[3].integer_value=teeth_shift;
      pars[4].type=TYPE_INT;
      pars[4].integer_value=lips_period;
      pars[5].type=TYPE_INT;
      pars[5].integer_value=lips_shift;
      //--- tipo de suavizado
      pars[6].type=TYPE_INT;
      pars[6].integer_value=MA_method;
      //--- tipo de precio
      pars[7].type=TYPE_INT;
      pars[7].integer_value=applied_price;
      //--- crearemos el manejador
      handle=IndicatorCreate(name,period,IND_GATOR,8,pars);
     }
//--- si no se puede crear el manejador
   if(handle==INVALID_HANDLE)
     {
      //--- avisaremos sobre el fallo y mostraremos el número del error
      PrintFormat("Fallo al crear el manejador del indicador iGator para el par %s/%s, código del error %d",
                  name,
                  EnumToString(period),
                  GetLastError());
      //--- el trabajo del indicador se finaliza anticipadamente
      return(INIT_FAILED);
     }
//--- mostraremos sobre qué par símbolo/período ha sido calculado el indicador Gator Oscillator
   short_name=StringFormat("iGator(%s/%s, %d, %d ,%d, %d, %d, %d)",name,EnumToString(period),
                           jaw_period,jaw_shift,teeth_period,teeth_shift,lips_period,lips_shift);
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- inicialización correcta del indicador  
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- número de valores copiados desde el indicador iGator
   int values_to_copy;
//--- vamos a averiguar el número de valores calculados en el indicador
   int calculated=BarsCalculated(handle);
   if(calculated<=0)
     {
      PrintFormat("BarsCalculated() ha devuelto %d, el código del error %d",calculated,GetLastError());
      return(0);
     }
//--- si se trata de la primera inicialización de la calculación de nuestro indicador o se ha cambiado el número de valores en el indicador iGator
//--- o si es necesario calcular el indicador para dos o más barras (entonces algo se ha cambiado en el historial)
   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
     {
      //--- si el array GatorUpBuffer supera el número de valores en el indicador iGator sobre el par symbol/period, entonces no copiamos todo 
      //--- en caso contrario, copiaremos menos que el tamaño de los búfers indicadores
      if(calculated>rates_total) values_to_copy=rates_total;
      else                       values_to_copy=calculated;
     }
   else
     {
      //--- significa que no es la primera vez que se calcula nuestro indicador y desde el momento de la primera llamada de OnCalculate())
      //--- se ha añadido no más de una barra para la calculación
      values_to_copy=(rates_total-prev_calculated)+1;
     }
//--- llenamos los arrays con los valores desde el indicador Gator Oscillator
//--- si FillArraysFromBuffer ha devuelto false, significa que los datos aún no están listos - entonces finalizamos el proceso
   if(!FillArraysFromBuffers(GatorUpBuffer,GatorUpColors,GatorDownBuffer,GatorDownColors,
      shift,handle,values_to_copy)) return(0);
//--- creamos el mensaje
   string comm=StringFormat("%s ==>  Actualizados los valores en el indicador %s: %d",
                            TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                            short_name,
                            values_to_copy);
//--- mostraremos en el gráfico un mensaje de servicio
   Comment(comm);
//--- recordaremos el número de valores en el indicador Gator Oscillator
   bars_calculated=calculated;
//--- devolveremos el valor prev_calculated para la siguiente llamada
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Llenamos los búfers indicadores desde el indicador iGator        |
//+------------------------------------------------------------------+
bool FillArraysFromBuffers(double &ups_buffer[],         // búfer indicador para el histograma superior
                           double &up_color_buffer[],    // búfer indicador para los índices de precios del histograma superior
                           double &downs_buffer[],       // búfer indicador para el histograma inferior
                           double &downs_color_buffer[], // búfer indicador para los índices de precios del histograma inferior
                           int u_shift,                  // desplazamiento para el histograma superior e inferior
                           int ind_handle,               // manejador del indicador iGator
                           int amount                    // número de valores a copiar
                           )
  {
//--- actualizaremos el código del error
   ResetLastError();
//--- llenamos una parte del array GatorUpBuffer con los valores desde el búfer indicador con el índice 0
   if(CopyBuffer(ind_handle,0,-u_shift,amount,ups_buffer)<0)
     {
      //--- si el proceso de copiado ha fallado, comunicaremos el código del error
      PrintFormat("Fallo al copiar los datos desde el indicador iGator, código del error %d",GetLastError());
      //--- finalizaremos con el resultado nulo - eso quiere decir que el indicador será considerado como no calculado
      return(false);
     }
 
//--- llenamos una parte del array GatorUpColors con los valores desde el búfer indicador con el índice 1
   if(CopyBuffer(ind_handle,1,-u_shift,amount,up_color_buffer)<0)
     {
      //--- si el proceso de copiado ha fallado, comunicaremos el código del error
      PrintFormat("Fallo al copiar los datos desde el indicador iGator, código del error %d",GetLastError());
      //--- finalizaremos con el resultado nulo - eso quiere decir que el indicador será considerado como no calculado
      return(false);
     }
 
//--- llenamos una parte del array GatorDownBuffer con los valores desde el búfer indicador bajo el índice 2
   if(CopyBuffer(ind_handle,2,-u_shift,amount,downs_buffer)<0)
     {
      //--- si el proceso de copiado ha fallado, comunicaremos el código del error
      PrintFormat("Fallo al copiar los datos desde el indicador iGator, código del error %d",GetLastError());
      //--- finalizaremos con el resultado nulo - eso quiere decir que el indicador será considerado como no calculado
      return(false);
     }
 
//--- llenamos una parte del array GatorDownColors con los valores desde el búfer indicador con el índice 3
   if(CopyBuffer(ind_handle,3,-u_shift,amount,downs_color_buffer)<0)
     {
      //--- si el proceso de copiado ha fallado, comunicaremos el código del error
      PrintFormat("Fallo al copiar los datos desde el indicador iGator, código del error %d",GetLastError());
      //--- finalizaremos con el resultado nulo - eso quiere decir que el indicador será considerado como no calculado
      return(false);
     }
//--- todo ha salido bien
   return(true);
  }
//+------------------------------------------------------------------+
//| Indicator deinitialization function                              |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   if(handle!=INVALID_HANDLE)
      IndicatorRelease(handle);
//--- limpiaremos el gráfico tras eliminar el indicador
   Comment("");
  }