MQL5 Wizard - Señales de comercio basadas en Morning/Evening Stars + Estocástico - Asesor Experto para MetaTrader 5

MQL5 Wizard le permite la creación de Asesores Expertos confeccionados en base a las clases de la libreria standard entregadas junto con el terminal del cliente (ver Creación de Asesores Expertos en MQL5 Wizard para más detalles) Permite comprobar sus ideas comerciales de forma rápida, lo único que necesita es crear sus propias clases de señales de operación. La estructura de esta clase y el ejemplo se puede encontrar en el artículo MQL5 Wizard: Cómo crear un módulo de señales de trading.

La idea genérica es la siguiente: la clase de señales de comercio se deriva de CExpertSignal, lo siguiente, es necesario reemplazar los métodos virtuales LongCondition() y ShortCondition() con sus propios métodos.

Hay un libro "Estrategias de mejores traders" (en ruso), allí hay muchas estrategias de negociación que se consideran, nos centraremos en la inversión de los patrones de vela, confirmados por los osciladores Estocástico, CCI, MFI y RSI .

La mejor manera es crear una clase separada, derivada de CExpertSignal para la comprobación de la formación de patrones de velas. Para la confirmación de las señales comerciales, generadas por los patrones de vela, es suficiente con escribir la clase, derivada de CCandlePattern y agregar allí las características necesarias (por ejemplo, la confirmación por osciladores).

Aquí vamos a considerar las señales, basadas en patrones de velas de reversa "Morning Star/Evening Star" (Morning Doji Star/Evening Doji Star) , confirmadas por el indicador Estocástico . El módulo de señales de comercio se basa en la clase CCandlePattern , es un simple ejemplo de su uso para la creación de las señales comerciales con los patrones de vela.

1. Patrones de vela de reversa "Morning Star" y "Evening Star"

1.1. Morning Star

Este patrón indica la reversión de la tendencia bajista, este consiste en tres velas (Fig. 1). Después de una vela negra larga hay una vela (el color no es importante) con un cuerpo pequeño, que se encuentra fuera del cuerpo de la vela negra. El pequeño cuerpo de una vela significa que la fuerza de los toros y los osos es igual y el mercado está listo para cambiar la tendencia.

La tercera vela del patrón es la vela alcista, el cuerpo no se solapa con el cuerpo de la segunda vela, y el precio de cierre se encuentra en el interior del cuerpo de la primera vela (bajista). El modelo de vela resultante se representa en la Figura 1.

En el caso que la segunda vela sea una vela doji, el modelo se llama "Morning Doji Star".

Figura 1. Patrones de vela "Morning Star" y "Morning Doji Star"

El Reconocimiento de patrones "Morning Star" esta implementado en los métodos CheckPatternMorningStar() y CheckPatternMorningDoji() de la Clase CCandlePattern :

//+------------------------------------------------------------------+
//| Comprueba la formación del patrón "Morning Star"                 |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternMorningStar()
  {
//--- Morning Star
   if((Open(3)-Close(3)>AvgBody(1))             && // vela bajista, su cuerpo es más grande que la media del cuerpo de la vela
      (MathAbs(Close(2)-Open(2))<AvgBody(1)*0.5) && // la segunda vela tiene el cuerpo pequeño (inferior a la mitad de la media del cuerpo)
      (Close(2)<Close(3))                       && // el cierre de la segunda vela es inferior al cierre de la primera 
      (Open(2)<Open(3))                         && // la apertura de la segunda vela es inferior a la apertura de la primera
      (Close(1)>MidOpenClose(3)))                  // el cierre de la última vela completada es más alto que el centro de la primera 
      return(true);
//---
   return(false);
  }
//+------------------------------------------------------------------+
//| Comprueba la formación del patrón "Morning Doji Star"            |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternMorningDoji()
  {
//--- Morning Doji Star
   if((Open(3)-Close(3)>AvgBody(1)) && // vela bajista con el cuerpo mayor que la media del cuerpo de la vela 
      (AvgBody(2)<AvgBody(1)*0.1)   && // la segunda vela tiene un cuerpo muy pequeño (doji) 
      (Close(2)<Close(3))           && // el cierre de la segunda vela es inferior al cierre de la primera 
      (Open(2)<Open(3))             && // la apertura de la segunda vela es inferior a la apertura de la primera
      (Open(1)>Close(2))            && // un gap al alza en la última vela completada
      (Close(1)>Close(2)))             // el cierre de la última vela completada es mayor que el cierre de la segunda
      return(true);
//---
   return(false);
  }

1.2. Evening Star

Este patrón indica la reversión de la tendencia alcista, este consiste en tres velas (Fig. 2). Después de una vela blanca larga hay una vela (el color no es importante) con un cuerpo pequeño, que se encuentra fuera del cuerpo de la vela blanca. El pequeño cuerpo de una vela significa que la fuerza de los toros y los osos es igual y el mercado está listo para cambiar la tendencia.

La tercera vela del patrón es la vela bajista, el cuerpo no se solapa con el cuerpo de la segunda vela, y el precio de cierre se encuentra en el interior del cuerpo de la primera vela (alcista). El modelo de vela resultante se representa en la Figura 2.

En el caso que la segunda vela sea una vela doji, el modelo se llama "Evening Doji Star".

Figura 2. Patrones de vela "Evening Star" y "Evening Doji Star"

Estos son los métodos para la identificación de patrones "Evening Star" y "Evening Doji Star" :

//+------------------------------------------------------------------+
//| Comprueba la formación del patrón "Evening Star"                 |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternEveningStar()
  {
//--- Evening Star
   if((Close(3)-Open(3)>AvgBody(1))             && // vela alcista con el cuerpo superior a la media 
      (MathAbs(Close(2)-Open(2))<AvgBody(1)*0.5) && // la segunda vela tiene un cuerpo pequeño (menos de la mitad de la media)
      (Close(2)>Close(3))                       && // el cierre de la segunda vela es más alto que el cierre de la primera
      (Open(2)>Open(3))                         && // la apertura de la segunda vela es más alta que la apertura de la primera
      (Close(1)<MidOpenClose(3)))                  // el cierre de la última vela completada es más bajo que el centro de la primera 
      return(true);
//---
   return(false);
  }
//+------------------------------------------------------------------+
//| Comprueba la formación del patrón "Evening Doji Star"            |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternEveningDoji()
  {
//--- Evening Doji Star
   if((Close(3)-Open(3)>AvgBody(1)) && // vela alcista con el cuerpo superior a la media 
      (AvgBody(2)<AvgBody(1)*0.1)   && // la segunda vela tiene un cuerpo muy pequeño (doji) 
      (Close(2)>Close(3))           && // el cierre de la segunda vela es más alto que el cierre de la primera
      (Open(2)>Open(3))             && // la apertura de la segunda vela es más alta que la apertura de la primera
      (Open(1)<Close(2))            && // gap a la baja en la última vela completada
      (Close(1)<Close(2)))             // el cierre de la última vela completada es más bajo que el cierre de la segunda 
      return(true);
//---
   return(false);
  }

2. Señales de comercio, confirmadas por el indicador Estocástico

Las señales de comercio para abrir posiciones largas o cortas deben ser confirmadas por el oscilador Estocástico. La línea %D de la señal% debe ser mayor / menor que el correspondiente nivel crítico (30 o 70).

El cierre de la posición abierta depende de los valores de %D del indicador. Se puede hacer de 2 formas:

1. si la línea D% ha alcanzado el nivel crítico opuesto (80 para la posición larga y 20 para la posición corta)
2. si la señal inversa no está confirmada (cuando la línea% D alcanza los siguientes niveles: 20 para la posición larga y 80 para la posición corta)

Figura 3. Patrón "Evening Star" pattern, confirmado por indicador Estocástico

• int CH_HM_Stoch::LongCondition() - comprueba las condiciones para abrir posiciones largas (devuelve 80) y cierra la posición corta (devuelve 40);
  
• int CH_HM_Stoch::ShortCondition() - comprueba las condiciones para abrir una posición corta (devuelve 80) y cierra la posición larga (devuelve 40).

2.1. Abre una posición larga/Cierra una posición corta

1. La formación del patrón "Morning Star" debe ser confirmada por el indicador Estocástico: StochSignal(1)<30 (el valor de la línea de señal del indicador Estocástico de la última barra completada tiene que ser menos de 30).

2. La posición corta debe ser cerrada si la línea de señal del indicador Estocástico a cruzado al alza los niveles 20 o 80.

//+------------------------------------------------------------------+
//| Comprueba las condiciones para las entradas y salidas al mercado |
//| 1) Entrada al mercado (abrir posición larga, resultado=80)       |
//| 2) Salida del mercado (cerrar posición corta, resultado=40)      |
//+------------------------------------------------------------------+
int CMS_ES_Stoch::LongCondition()
  {
   int result=0;
//--- idx se puede utilizar para determinar el modo de trabajo del Asesor Experto
//--- idx=0 - idx = 0 - en este caso el EA comprueba las condiciones del comercio en cada tick
//--- idx=1 - en este caso el EA comprueba la condición de comercio sólo en las barras nuevas
   int idx   =StartIndex();
//--- comprobación de las condiciones para abrir posiciones largas
//--- formación de patrón Morning Star pattern y la linea de señal<30
  if (CheckCandlestickPattern(CANDLE_PATTERN_MORNING_STAR) && (StochSignal(1)<30))
     result=80;
//--- comprobación de las condiciones para cerrar la posición corta
//--- cruce de la línea de señal de los niveles de sobre compra / sobre venta (a la baja 20, al alza 80)
   if((((StochSignal(1)>20) && (StochSignal(2)<20)) ||
       ((StochSignal(1)>80) && (StochSignal(2)<80))))
     result=40;
//--- devuelve el resultado
   return(result);
  }

2.2. Abrir la posición corta/Cerrar la posición larga

1. La formación del patrón "Evening Star" debe ser confirmada por el indicador Estocástico: StochSignal(1)>70 (el valor de la línea de señal del indicador Estocástico de la última barra completada tiene que ser mayor de 70).

2. La posición larga debe ser cerrada si la línea de señal del indicator Estocástico ha cruzado a la baja los niveles 80 o 20.

//+--------------------------------------------------------------------+
//| Comprueba las condiciones para la entrada y salida del mercado     |
//| 1) Entrada en el mercado (abre una posición corta, resultado = 80) |
//| 2) Salida del mercado (cierra posición larga, resultado = 40)      |
//+--------------------------------------------------------------------+
int CMS_ES_Stoch::ShortCondition()
  {
   int result=0;
//--- idx se puede utilizar para determinar el modo de trabajo del Asesor Experto
//--- idx=0 - en este caso el EA comprueba las condiciones de comercio en cada tick
//--- idx=1 - idx=1 - en este caso, el EA comprueba las condiciones de comercio sólo en las barras nuevas
   int idx   =StartIndex();
//--- comprobación de las condiciones para abrir una posición corta
//--- formación del patrón Evening Star y linea de señal>70
  if (CheckCandlestickPattern(CANDLE_PATTERN_EVENING_STAR) && (StochSignal(1)>70))
     result=80;
//--- comprobación de las condiciones para abrir posiciones largas
//--- cruce de la línea de señal de los niveles de sobre compra / sobre venta (a la baja 80, al alza 20)
   if((((StochSignal(1)<80) && (StochSignal(2)>80)) ||
       ((StochSignal(1)<20) && (StochSignal(2)>20))))
     result=40;
//--- devuelve el resultado
   return(result);
  }

2.3. Creando el Asesor Experto utilizando MQL5 Wizard

Para crear un Asesor Experto lanzaremos MQL5 Wizard:

Fig. 4. Creando el Asesor Experto utilizando MQL5 Wizard

Vamos a especificar el nombre del Asesor Experto:

Fig. 5. Propiedades generales del Asesor Experto

Después de eso tenemos que seleccionar los módulos de señales comerciales utilizados.

Fig. 6. Propiedades de la señal del Asesor Experto

En nuestro caso usamos sólo un módulo de señales comerciales.

Añadiendo los módulos de señales de comercio de las "Señales basadas en Morning/Evening Stars por Estocástico":

Fig. 7. Propiedades de la señal del Asesor Experto

El módulo de señales de comercio añadido:

Fig. 8. Propiedades de la señal del Asesor Experto

Puedes seleccionar cualquier propiedad de trailing, pero vamos a utilizar "Trailing Stop not used":

Fig. 9. Propiedades de trailing del Asesor Experto

En cuanto a las propiedades de manejo del dinero, vamos a utilizar "Trading with fixed trade volume":

Fig. 10. Propiedades de la administración del dinero del Asesor Experto "

Al presionar el botón "Finish" obtendremos el código generado del Asesor Experto, ubicado en Expert_AMS_ES_Stoch.mq5, que se guardará en terminal_data_folder\MQL5\Experts\.

Loa parámetros de entrada generados por defecto del Asesor Experto

//--- entradas para la señal principal
input int            Signal_ThresholdOpen   =10;     // Valor umbral de la señal para abrir [0...100]
input int            Signal_ThresholdClose  =10;     // Valor umbral de señal la para cerrar [0...100]
input double         Signal_PriceLevel      =0.0;    // Nivel de precio para ejecutar una transacción
input double         Signal_StopLevel       =50.0;   // Nivel de Stop Loss(en puntos)
input double         Signal_TakeLevel       =50.0;   // Nivel de Take Profit(en puntos)

deben ser reemplazado por:

//--- entradas para la señal principal
input int            Signal_ThresholdOpen   =40;     // Valor umbral de señal la para cerrar [0...100]
input int            Signal_ThresholdClose  =20;     // Valor umbral de señal la para cerrar [0...100]
input double         Signal_PriceLevel      =0.0;    // Nivel de precio para ejecutar una transacción
input double         Signal_StopLevel       =0.0;    // Nivel de Stop Loss(en puntos)
input double         Signal_TakeLevel       =0.0;    // Nivel de Take Profit(en puntos)

Los parámetros de entrada Signal_ThresholdOpen / Signal_ThresholdClose permiten especificar los niveles de umbral para la apertura y cierre de posiciones.

En el código de los métodos LongCondition () y ShortCondition () de la clase de señales de comercio hemos especificado los valores fijos del umbral:

• Abrir posición: 80;
• Cerrar posición: 40.
  

Los valores de los parámetros de entrada Signal_StopLevel y Signal_TakeLevel se establecen en 0, esto significa que el cierre de las posiciones se hará sólo cuando las condiciones de cierre sean verdaderas.

2.4. Resultados del backtesting del Historial

Vamos a considerar el backtesting del Asesor Experto sobre los datos históricos (EURUSD H1, período de prueba: 2000.01.01-2011.03.16, PeriodK=12, PeriodD=8, PeriodSlow=29, MA_period=4).

En la creación del Asesor Experto se utilizó el volumen fijo (Trading Fixed Lot, 0.1), El algoritmo de Trailing Stop algorithm no se utiliza (Trailing not used).

Fig. 11. Resultados de las pruebas del Asesor Experto, basadas en Morning/Evening Stars + Estocástico"

El mejor conjunto de parámetros de entrada se puede encontrar utilizando el Strategy Tester del terminal de cliente MetaTrader 5 .

El código del Asesor Experto, creado por MQL5 Wizard se adjunta en expert_ams_es_stoch.mq5.