DatabaseImport

long  DatabaseImport(
   int           database,          // handle de la base de données obtenu avec DatabaseOpen
   const string  table,             // nom d'une table dans laquelle insérer des données
   const string  filename,          // nom du fichier contenant les données à importer
   uint          flags,             // combinaison de flags
   const string  separator,         // séparateur de données
   ulong         skip_rows,         // le nombre de lignes à ignorer
   const string  skip_comments      // chaîne de caractères identifiant les commentaires
   );

//+------------------------------------------------------------------+
//| Fonction de démarrage du programme                               |
//+------------------------------------------------------------------+
void OnStart()
 {
  string csv_filename;
//--- récupèrle noms des fichiers texte à télécharger depuis le répertoire commun des terminaux clients
  string filenames[];
  if(FileSelectDialog("Sélectionner un fichier CSV pour télécharger une table", NULL,
                      "Text files (*.csv)|*.csv",
                      FSD_WRITE_FILE|FSD_COMMON_FOLDER, filenames, "data.csv")>0)
   {
    //--- affiche le nom de chaque fichier sélectionné
    if(ArraySize(filenames)==1)
      csv_filename=filenames[0];
    else
     {
      Print("Erreur inconnue lors de la sélection du fichier. Code d'erreur ", GetLastError());
      return;
     }
   }
  else
   {
    Print("Fichier CSV non sélectionné");
    return;
   }
//--- crée ou ouvre une base de données
  string db_filename="test.sqlite";
  int db=DatabaseOpen(db_filename, DATABASE_OPEN_READWRITE|DATABASE_OPEN_CREATE);
//--- vérifie si la table TEST existe
  if(DatabaseTableExists(db, "TEST"))
   {
    //--- supprime la table TEST 
    if(!DatabaseExecute(db, "DROP TABLE IF EXISTS TEST"))
     {
      Print("Echec de la suppression de la table TEST avec le code ", GetLastError());
      DatabaseClose(db);
      return;
     }
   }
  //--- importe les entrées du fichier dans la table TEST
  long imported=DatabaseImport(db, "TEST", csv_filename, DATABASE_IMPORT_HEADER|DATABASE_IMPORT_COMMON_FOLDER|DATABASE_IMPORT_APPEND, ";", 0, NULL);
  if(imported>0)
   {
    Print(imported," lignes importées dans la table TEST");
    DatabasePrint(db,"SELECT * FROM TEST",DATABASE_PRINT_NO_INDEX);
   }
  else
    {
     Print("Echec de DatabaseImport(). Erreur ",GetLastError());
    }
//--- ferme la base de données
  DatabaseClose(db);
  PrintFormat("Base de données : %s fermée", db_filename);
 }