外汇交易ABC

MetaQuotes | 13 二月, 2008

回顾历史

我们的时代

货币存款

标准份额大小 - 标准手数

在一种货币与另外一种货币交换时,使用的单位为"标准手数".以标准手数来进行买卖.对于不同的货币对标准手数存在不同值. 目前,最大的货币对标准手数值等于100 000 .但什么是 100 000呢?当我们买进时,需要支付金钱.当我们卖出时,可以获取金钱.但是对于货币对,我们买卖的同时也可以获得一定盈利.这就是为什么通常我们获取第一个货币价格关系到第二弟货币的原因.对于 EURUSD标准手数为100 000欧元.如果我们买进一个 EURUSD标准手,意味着我们用 100 000 欧元并换取一定数量的美元.由于收入和支出必须保持平衡 100 000 欧元 = X 美元.那么我们怎样去计算呢?让我们在表达式中用美元还原欧元:

EURO= k*USD
  k 表示 EURUSD的交换汇率;
100 000 (k*USD) = X USD => X= k*100 000;
如果当前 EURUSD汇率为 1.25, 就是X=125 000.

由上面的计算可以得出 EURUSD标准手数, 我们的 100 000 欧元可以换取得到125 000 美元.有时有人说 - 买进欧元和卖出美元就是表示买进 EURUSD .对于货币对的标准手数的信息您可以使用 MarketInfo() 函数获取.例如:

MarketInfo(Symbol(), MODE_LOTSIZE);

您同样可以获得货币对名称文本和函数

MarketInfo("EURUSD",  MODE_LOTSIZE);

将返回100 000.会被写入帮助文件: MODE_LOTSIZE 是在货币对基础的份额大小.对于EURUSD 货币对的基础货币为 EUR (*).对于 CHFJPY货币对的基础货币对为瑞士法郎,相关的价格将会以瑞士法郎表示.

交易结果

杠杆和保证金

保证金计算

点数 - 最小价格改变

在外汇交易中的货币对每种货币的差异不仅在自己的特性上，同样在他们汇率的小数点数量上。例如， GBPJPY的汇率，2006年12月29日为 233.18,同一天 GBPUSD 的汇率为1.9587。小数点的总数可以使用函数设置

MarketInfo(Symbol(), MODE_DIGITS);

例如,函数

MarketInfo("GBPJPY", MODE_DIGITS);

将返回2.

相应地，对于当前不同的货币对最小价格的改变也将不同。这个值通常等于 0.01，对于货币对 EURUSD 为 0.0001。在当前开价中这个最小价格改变被称为 点，可以使用函数获取:

MarketInfo(Symbol(), MODE_POINT);

对于当前货币对,函数的值

MarketInfo(Symbol(), MODE_POINT); and MarketInfo(Symbol(), MODE_TICKSIZE);

相同。

在货币存款中的价格点

估测风险，当价格移动至一定点数交易者必须知道开仓的亏损数量。或者相反，在亏损点上计算可以接受的亏损量。这样，需要使用函数

MarketInfo(Symbol(), MODE_TICKVALUE);

在货币存款中返回点值。
必须要注意的是对于货币对点值将会改变，第二个值不是货币存款。

每个标准手的保证金

最后的函数考虑到

MarketInfo(Symbol(), MODE_MARGINREQUIRED);

以 卖出价 返回一个标准手的价格。

以上范例的函数使用

下面您可以看到脚本显示的上面12组货币对的函数数据。必须注意脚本的自定义函数 MarginCalculate()以买入价返回的标准手数。脚本允许学习申请 MQL4 函数使用到智能交易的金钱管理和风险管理的计算中。.

//+------------------------------------------------------------------+
//|                                          SimplySpecification.mq4 |
//|                      Copyright © 2007, MetaQuotes Software Corp. |
//|                                       https://www.metaquotes.net/ |
//+------------------------------------------------------------------+
string SymbolsArray[13] = {"","USDCHF","GBPUSD","EURUSD","USDJPY",
"AUDUSD","USDCAD","EURGBP","EURAUD","EURCHF","EURJPY","GBPJPY","GBPCHF"};
//+------------------------------------------------------------------+
//| string SymbolByNumber                                            |
//+------------------------------------------------------------------+
string GetSymbolString(int Number)
  {
//----
   string res = "";
   res = SymbolsArray[Number];   
//----
   return(res);
  }
//+------------------------------------------------------------------+
//| A very simple function to calculate margin for Forex symbols.    |
//| It automatically calculates in the account's base currency and   |
//| does not work for complicated rates that do not have direct      |
//| recalculation into the trade account's base currency.            |
//+------------------------------------------------------------------+
double MarginCalculate(string symbol, double volume)
  {
   string first    = StringSubstr(symbol,0,3); // the first symbol, for example,  EUR
   string second   = StringSubstr(symbol,3,3); // the second symbol, for example, USD
   string currency = AccountCurrency();        // deposit currency, for example,  USD
   double leverage = AccountLeverage();        // leverage, for example,          100
// contract size, for example, 100000
   double contract = MarketInfo(symbol, MODE_LOTSIZE);
   double bid      = MarketInfo(symbol, MODE_BID);      // Bid price
//---- allow only standard forex symbols like XXXYYY
   if(StringLen(symbol) != 6)
     {
      Print("MarginCalculate: '",symbol,"' must be standard forex symbol XXXYYY");
      return(0.0);
     }
//---- check for data availability
   if(bid <= 0 || contract <= 0) 
     {
      Print("MarginCalculate: no market information for '",symbol,"'");
      return(0.0);
     }
//---- check the simplest variations - without cross currencies
   if(first == currency)   
       return(contract*volume / leverage);           // USDxxx
   if(second == currency)  
       return(contract*bid*volume / leverage);       // xxxUSD
//---- check normal cross currencies, search for direct conversion through deposit currency
   string base = currency + first;                   // USDxxx
   if(MarketInfo(base, MODE_BID) > 0) 
       return(contract / MarketInfo(base, MODE_BID)*volume / leverage);
//---- try vice versa
   base = first + currency;                          // xxxUSD
   if(MarketInfo(base, MODE_BID) > 0) 
       return(contract*MarketInfo(base, MODE_BID)*volume / leverage);
//---- direct conversion is impossible
   Print("MarginCalculate: can not convert '",symbol,"'");
   return(0.0);
  }
//+------------------------------------------------------------------+
//| script program start function                                    |
//+------------------------------------------------------------------+
int start()
  {
//----
   for(int i = 1; i < 13; i++)
     {
      Print("Symbol=",GetSymbolString(i),"  spread=",MarketInfo(GetSymbolString(i),
      MODE_SPREAD),"  margin at 1 lot=",MarginCalculate(GetSymbolString(i),1),
      "  MODE_TICKVALUE=",MarketInfo(GetSymbolString(i),MODE_TICKVALUE),
      ", MODE_TICKSIZE=",MarketInfo(GetSymbolString(i),MODE_TICKSIZE),
      " MODE_MARGINREQUIRED=",MarketInfo(GetSymbolString(i),MODE_MARGINREQUIRED));
     } 
//----
   return(0);
  }
//+------------------------------------------------------------------+

*大多数情况下，货币对的基础货币是在货币对的第一位，当然，也存在不同的服务器设定。