Вопросы от начинающих MQL5 MT5 MetaTrader 5 - страница 1192

Новый комментарий
 
Artem Mordvinkin:


Да там русским по белому написано что символы автоматом подключаются при тестировании 

При обращении к ним.
 
Artem Mordvinkin:


Да там русским по белому написано что символы автоматом подключаются при тестировании 

Чтобы создать индикатор, сначала нужно подключить символ в Обзор рынка (в Вашем случае в Обзор рынка тестера).

 
Artyom Trishkin:
Запросите с каждого нужного символа любые данные.

Они по SymbolSelect() отсутствуют - не выбираются

Уважаемые господа Прежде чем меня направлять в публикации (за что спасибо) проверьте - работают ли ваши мультивалютники в тестере И если они работают, то имеет смысл 

 
Artem Mordvinkin:

Они по SymbolSelect() отсутствуют - не выбираются

Уважаемые господа Прежде чем меня направлять в публикации (за что спасибо) проверьте - работают ли ваши мультивалютники в тестере И если они работают, то имеет смысл 

Работают. На последнем билде. Проблем никаких.
 
Artyom Trishkin:
Работают. На последнем билде. Проблем никаких.

Как вы их (символы) подключили - подскажите, пжлст, какая функция?

 
Artem Mordvinkin:

Как вы их (символы) подключили - подскажите, пжлст, какая функция?

SymbolSelect(имя символа,true);

 
Vladimir Karputov:

SymbolSelect(имя символа,true);

Делаю так же

SymbolSelect(EURUSD_inst, true);
  SymbolSelect(GBPUSD_inst, true);
  SymbolSelect(USDJPY_inst, true);
  SymbolSelect(AUDUSD_inst, true);


Получаю вот так

2020.03.09 19:19:45.766 symbol EURUSDrfd does not exist

2020.03.09 19:19:45.766 symbol USDJPYrfd does not exist

2020.03.09 19:19:45.766 symbol AUDUSDrfd does not exist


Кабель не выдает ошибку тк выбран в самом тестере

Названия символов верные. 


UPD сдается мне, что надо что-то сделать в настройках самого терминала. Если все работало до последнего билда, то дело не в коде. Не видит тестер символы.

 
Artem Mordvinkin:


2020.03.09 19:19:45.766 symbol EURUSDrfd does not exist

2020.03.09 19:19:45.766 symbol USDJPYrfd does not exist

2020.03.09 19:19:45.766 symbol AUDUSDrfd does not exist


Кабель не выдает ошибку тк выбран в самом тестере

Что это? Где код? Как Вы это получаете? Тем более Вы выбираете совершенной другие символы.

 
Vladimir Karputov:

Что это? Где код? Как Вы это получаете? Тем более Вы выбираете совершенной другие символы.

понял, давайте так 

Дано (название символов)


Код (фрагменты)

//----------------------------название инструмента
string EURUSD_inst = "EURUSDrfd";
string GBPUSD_inst = "GBPUSDrfd";
string AUDUSD_inst = "AUDUSDrfd";
string USDJPY_inst = "USDJPYrfd";


void OnTick()
  {
  SymbolSelect(EURUSD_inst, true);
  SymbolSelect(GBPUSD_inst, true);
  SymbolSelect(USDJPY_inst, true);
  SymbolSelect(AUDUSD_inst, true);
}

Для примера выберем кабель в тестере


Запускаем и 

2020.03.09 19:19:45.766 symbol EURUSDrfd does not exist

2020.03.09 19:19:45.766 symbol USDJPYrfd does not exist

2020.03.09 19:19:45.766 symbol AUDUSDrfd does not exist

По кабелю ошибки нет - он же принудительно в тестере выбран

И на всякий случай скажу, что такая проблема только в тестере. И что сове уже несколько лет, а ошибке 2 дня и, что так по всем мультивалютным совам моим.
 

Пример создания индикатора iMA на символе 'USDJPY', при этом тестер запускается на 'EURUSD'.

//+------------------------------------------------------------------+
//|                                        iMA Values on a Chart.mq5 |
//|                              Copyright © 2019, Vladimir Karputov |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2019, Vladimir Karputov"
#property version   "1.001"
//--- input parameters
input  string              Inp_MA_symbol        = "USDJPY";    // MA: symbol name
input ENUM_TIMEFRAMES      Inp_MA_period        = PERIOD_D1;   // MA: timeframe
input int                  Inp_MA_ma_period     = 12;          // MA: averaging period
input int                  Inp_MA_ma_shift      = 5;           // MA: horizontal shift
input ENUM_MA_METHOD       Inp_MA_ma_method     = MODE_SMA;    // MA: smoothing type
input ENUM_APPLIED_PRICE   Inp_MA_applied_price = PRICE_CLOSE; // MA: type of price
//---
int    handle_iMA;                           // variable for storing the handle of the iMA indicator
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   if(!SymbolSelect(Inp_MA_symbol,true))
     {
      PrintFormat("Failed select symbol %s",
                  Inp_MA_symbol);
      return(INIT_FAILED);
     }
//--- create handle of the indicator iMA
   handle_iMA=iMA(Inp_MA_symbol,Inp_MA_period,Inp_MA_ma_period,Inp_MA_ma_shift,
                  Inp_MA_ma_method,Inp_MA_applied_price);
//--- if the handle is not created
   if(handle_iMA==INVALID_HANDLE)
     {
      //--- tell about the failure and output the error code
      PrintFormat("Failed to create handle of the iMA indicator for the symbol %s/%s, error code %d",
                  Inp_MA_symbol,
                  EnumToString(Inp_MA_period),
                  GetLastError());
      //--- the indicator is stopped early
      return(INIT_FAILED);
     }
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   double array_ma[];
   ArraySetAsSeries(array_ma,true);
   int start_pos=0,count=3;
   if(!iGetArray(handle_iMA,0,start_pos,count,array_ma))
      return;

   string text="";
   for(int i=0; i<count; i++)
      text=text+IntegerToString(i)+": "+DoubleToString(array_ma[i],Digits()+1)+"\n";
//---
   Comment(text);
  }
//+------------------------------------------------------------------+
//| Get value of buffers                                             |
//+------------------------------------------------------------------+
bool iGetArray(const int handle,const int buffer,const int start_pos,
               const int count,double &arr_buffer[])
  {
   bool result=true;
   if(!ArrayIsDynamic(arr_buffer))
     {
      //if(InpPrintLog)
      PrintFormat("ERROR! EA: %s, FUNCTION: %s, this a no dynamic array!",__FILE__,__FUNCTION__);
      return(false);
     }
   ArrayFree(arr_buffer);
//--- reset error code
   ResetLastError();
//--- fill a part of the iBands array with values from the indicator buffer
   int copied=CopyBuffer(handle,buffer,start_pos,count,arr_buffer);
   if(copied!=count)
     {
      //--- if the copying fails, tell the error code
      //if(InpPrintLog)
      PrintFormat("ERROR! EA: %s, FUNCTION: %s, amount to copy: %d, copied: %d, error code %d",
                  __FILE__,__FUNCTION__,count,copied,GetLastError());
      //--- quit with zero result - it means that the indicator is considered as not calculated
      return(false);
     }
   return(result);
  }
//+------------------------------------------------------------------+

Результат всё корректно создаётся. Сначала выбирается символ, а ПОТОМ создаётся по нему индикатор.


Файлы:
iMA_Values_on_a_Chart.mq5  8 kb
1...118511861187118811891190119111921193119411951196119711981199...1520
Новый комментарий
Причина обращения: