//+------------------------------------------------------------------+
//| Demo_iAC.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "Индикатор демонстрирует, как нужно получать данные"
#property description "индикаторных буферов для технического индикатора iAC."
#property description "Символ и таймфрейм, на котором рассчитывается индикатор,"
#property description "задаются параметрами symbol и period."
#property description "Способ создания хэндла задается параметром 'type' (тип функции)."
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots 1
//--- построение iAC
#property indicator_label1 "iAC"
#property indicator_type1 DRAW_COLOR_HISTOGRAM
#property indicator_color1 clrGreen, clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//+------------------------------------------------------------------+
//| Перечисление способов создания хэндла |
//+------------------------------------------------------------------+
enum Creation
{
Call_iAC, // использовать iAC
Call_IndicatorCreate // использовать IndicatorCreate
};
//--- входные параметры
input Creation type=Call_iAC; // тип функции
input string symbol=" "; // символ
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // таймфрейм
//--- индикаторные буферы
double iACBuffer[];
double iACColors[];
//--- переменная для хранения хэндла индикатора iAC
int handle;
//--- переменная для хранения
string name=symbol;
//--- имя индикатора на графике
string short_name;
//--- будем хранить количество значений в индикаторе Accelerator Oscillator
int bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- привязка массивов к индикаторным буферам
SetIndexBuffer(0,iACBuffer,INDICATOR_DATA);
SetIndexBuffer(1,iACColors,INDICATOR_COLOR_INDEX);
//--- определимся с символом, на котором строится индикатор
name=symbol;
//--- удалим пробелы слева и справа
StringTrimRight(name);
StringTrimLeft(name);
//--- если после этого длина строки name нулевая
if(StringLen(name)==0)
{
//--- возьмем символ с графика, на котором запущен индикатор
name=_Symbol;
}
//--- создадим хэндл индикатора
if(type==Call_iAC)
handle=iAC(name,period);
else
handle=IndicatorCreate(name,period,IND_AC);
//--- если не удалось создать хэндл
if(handle==INVALID_HANDLE)
{
//--- сообщим о неудаче и выведем номер ошибки
PrintFormat("Не удалось создать хэндл индикатора iAC для пары %s/%s, код ошибки %d",
name,
EnumToString(period),
GetLastError());
//--- работа индикатора завершается досрочно
return(INIT_FAILED);
}
//--- покажем на какой паре символ/таймфрейм рассчитан индикатор Accelerator Oscillator
short_name=StringFormat("iAC(%s/%s)",name,EnumToString(period));
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- нормальное выполнение инициализации индикатора
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- количество копируемых значений из индикатора iAC
int values_to_copy;
//--- узнаем количество рассчитанных значений в индикаторе
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() вернул %d, код ошибки %d",calculated,GetLastError());
return(0);
}
//--- если это первый запуск вычислений нашего индикатора или изменилось количество значений в индикаторе iAC
//--- или если необходимо рассчитать индикатор для двух или более баров (значит что-то изменилось в истории)
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- если массив iACBuffer больше, чем значений в индикаторе iAC на паре symbol/period, то копируем не все
//--- в противном случае копировать будем меньше, чем размер индикаторных буферов
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- значит наш индикатор рассчитывается не в первый раз и с момента последнего вызова OnCalculate())
//--- для расчета добавилось не более одного бара
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- заполняем массивы iACBuffer и iACColors значениями из индикатора Accelerator Oscillator
//--- если FillArraysFromBuffer вернула false, значит данные не готовы - завершаем работу
if(!FillArraysFromBuffer(iACBuffer,iACColors,handle,values_to_copy)) return(0);
//--- сформируем сообщение
string comm=StringFormat("%s ==> Обновлено значений в индикаторе %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- выведем на график служебное сообщение
Comment(comm);
//--- запомним количество значений в индикаторе Accelerator Oscillator
bars_calculated=calculated;
//--- вернем значение prev_calculated для следующего вызова
return(rates_total);
}
//+------------------------------------------------------------------+
//| Заполняем индикаторные буферы из индикатора iAC |
//+------------------------------------------------------------------+
bool FillArraysFromBuffer(double &values[], // индикаторный буфер значений Accelerator Oscillator
double &color_indexes[], // цветовой буфер (для хранения индексов цвета)
int ind_handle, // хэндл индикатора iAС
int amount // количество копируемых значений
)
{
//--- сбросим код ошибки
ResetLastError();
//--- заполняем часть массива iACBuffer значениями из индикаторного буфера под индексом 0
if(CopyBuffer(ind_handle,0,0,amount,values)<0)
{
//--- если копирование не удалось, сообщим код ошибки
PrintFormat("Не удалось скопировать данные из индикатора iAC, код ошибки %d",GetLastError());
//--- завершим с нулевым результатом - это означает, что индикатор будет считаться нерассчитанным
return(false);
}
//--- теперь копируем индексы цветов
if(CopyBuffer(ind_handle,1,0,amount,color_indexes)<0)
{
//--- если копирование не удалось,сообщим код ошибки
PrintFormat("Не удалось скопировать значения цветов из индикатора iAC, код ошибки %d",GetLastError());
//--- завершим с нулевым результатом - это означает, что индикатор будет считаться нерассчитанным
return(false);
}
//--- все получилось
return(true);
}
//+------------------------------------------------------------------+
//| Indicator deinitialization function |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- почистим график при удалении индикатора
Comment("");
}
|