Forex トレーディングのイロハ

MetaQuotes | 17 2月, 2016

歴史を少し

現代

預金通貨

標準的契約サイズ－標準ロット

1通貨を別通貨に交換する際、『ロット』という概念を使います、ロットは売買される物品量です。ロットは異なる通貨ペアに対して異なる値を持ちます。現在では、ほとんどの通貨ペアは100,000（百）に等しいロット値を持ちます。ですが、何の 100,000 でしょうか？われわれが買う場合、物品にたいしてお金を出します。売るとき、物品に対してお金を受け取ります。ただ通貨の場合、ある通貨を別の通貨に対して得るため売買を同時に行います。これが、買うとき最初の通貨を得、それに応じて2番目の通貨を渡す、ということを考える一般的な方法である理由です。EURUSD に対する標準ロットは 100,000 ユーロです。EURUSD の標準1ロットを買う場合、それは 100,000 ユーロを得、ある数量の米ドルを渡すことを意味します。受け取り額と支払い額はつねに一致するため、100,000 ユーロ = X 米ドルとなります。それでは米ドルの額はどのように計算できるのでしょうか？この式でユーロと米ドルを入れ替えます。

EURO= k*USD
ここで k は EURUS の為替レートです。
100 000 (k*USD) = X USD => X= k*100 000;
現在の EURUSD の為替レートが 1.25 であれば、X=125,000　となります。

したがって、EURUSD の1ロットを買うと、100,000 ユーロを受け取り、125,000 米ドルを渡すのです。ユーロが買われ、米ドルが売られることについて 、EURUSD が買われた、と言われることがあります。契約仕様からの通貨ペアに対する標準ロットの価格に関する情報もMarketInfo() 関数によって入手できます。たとえば以下です。

MarketInfo(Symbol(), MODE_LOTSIZE);

また、通貨ペアのテキスト名を提示すると、関数

MarketInfo("EURUSD",  MODE_LOTSIZE);

は100,000 を返します。それはヘルプファイルに書かれてあります。MODE_LOTSIZE はシンボルベースの通貨での契約サイズです。EURUSD に対するべース通貨は EUR (*) です。CHFJPY に対するべース通貨はスイスフランで、それに応じ、1ロットの価格はそれぞれスイスフランで表現されます。

トレード結果

レバレッジとマージン

マージン決定

ポイント－最小価格変動

Forex における通貨ペアは、その特別な変動だけでなく、レートにある小数点以下の数によってもお互い異なります。たとえば、2006年12月29日時点の GBPJPY のレートは 233.18 で、一方 GBPUSD の同日終値は 1.9587 でした。小数点以下の数（精度）は以下の関数によって設定されます。

MarketInfo(Symbol(), MODE_DIGITS);

例えば、関数

MarketInfo("GBPJPY", MODE_DIGITS);

は2を返します。

それに対応して、異なる通貨に対する安値の変化も異なります。この値は円を含む通常ペアには 0.01 で、EURUSD に対しては 0.0001 です。クオート通貨における安値の値変化は ポイント と呼ばれ、以下の関数によって取得されます。

MarketInfo(Symbol(), MODE_POINT);

通貨ペアに対しては関数値

MarketInfo(Symbol(), MODE_POINT); and MarketInfo(Symbol(), MODE_TICKSIZE);

は同じです。

預金通貨におけるポイント価格

リスク判定をするには、トレーダーは価格が特定のポイント数に変動するとき、オープンしているポジションに対する損失サイズを知る必要があります。または逆に、資金の観点で損失サイズにおいて許容できる損失サイズをポイントで計算します。このためには以下の関数を利用します。

MarketInfo(Symbol(), MODE_TICKVALUE);

これは預金通貨における1ポイント値を返します。
1ポイント価格は通貨ペアに対して変化し、通貨ペアの2番目の値は預金通貨ではないことを忘れてはいけません。

ロットごとのマージン

最後に考察する関数

MarketInfo(Symbol(), MODE_MARGINREQUIRED);

は売りポジションを1ロットオープンするために必要な自由資産額を返します。すなわち Ask 価格での標準ロット価格です。

上記を考慮した関数の使用例

以下は、12 通貨ペアに関して前述を考慮した関数に対するデータ表示を行うスクリプトです。このスクリプトのカスタム関数 MarginCalculate() は入札価格（売却価格）における標準ロットの価格を返します。以下のスクリプトで、MQL4 の関数を Expert Advis での資金管理およびリスク管理のアルゴリズムに使用する関数に応用する方法を学ぶことができます。

//+------------------------------------------------------------------+
//|                                          SimplySpecification.mq4 |
//|                      Copyright © 2007, MetaQuotes Software Corp. |
//|                                       https://www.metaquotes.net/ |
//+------------------------------------------------------------------+
string SymbolsArray[13] = {"","USDCHF","GBPUSD","EURUSD","USDJPY",
"AUDUSD","USDCAD","EURGBP","EURAUD","EURCHF","EURJPY","GBPJPY","GBPCHF"};
//+------------------------------------------------------------------+
//| string SymbolByNumber                                            |
//+------------------------------------------------------------------+
string GetSymbolString(int Number)
  {
//----
   string res = "";
   res = SymbolsArray[Number];   
//----
   return(res);
  }
//+------------------------------------------------------------------+
//| A very simple function to calculate margin for Forex symbols.    |
//| It automatically calculates in the account's base currency and   |
//| does not work for complicated rates that do not have direct      |
//| recalculation into the trade account's base currency.            |
//+------------------------------------------------------------------+
double MarginCalculate(string symbol, double volume)
  {
   string first    = StringSubstr(symbol,0,3); // the first symbol, for example,  EUR
   string second   = StringSubstr(symbol,3,3); // the second symbol, for example, USD
   string currency = AccountCurrency();        // deposit currency, for example,  USD
   double leverage = AccountLeverage();        // leverage, for example,          100
// contract size, for example, 100000
   double contract = MarketInfo(symbol, MODE_LOTSIZE);
   double bid      = MarketInfo(symbol, MODE_BID);      // Bid price
//---- allow only standard forex symbols like XXXYYY
   if(StringLen(symbol) != 6)
     {
      Print("MarginCalculate: '",symbol,"' must be standard forex symbol XXXYYY");
      return(0.0);
     }
//---- check for data availability
   if(bid <= 0 || contract <= 0) 
     {
      Print("MarginCalculate: no market information for '",symbol,"'");
      return(0.0);
     }
//---- check the simplest variations - without cross currencies
   if(first == currency)   
       return(contract*volume / leverage);           // USDxxx
   if(second == currency)  
       return(contract*bid*volume / leverage);       // xxxUSD
//---- check normal cross currencies, search for direct conversion through deposit currency
   string base = currency + first;                   // USDxxx
   if(MarketInfo(base, MODE_BID) > 0) 
       return(contract / MarketInfo(base, MODE_BID)*volume / leverage);
//---- try vice versa
   base = first + currency;                          // xxxUSD
   if(MarketInfo(base, MODE_BID) > 0) 
       return(contract*MarketInfo(base, MODE_BID)*volume / leverage);
//---- direct conversion is impossible
   Print("MarginCalculate: can not convert '",symbol,"'");
   return(0.0);
  }
//+------------------------------------------------------------------+
//| script program start function                                    |
//+------------------------------------------------------------------+
int start()
  {
//----
   for(int i = 1; i < 13; i++)
     {
      Print("Symbol=",GetSymbolString(i),"  spread=",MarketInfo(GetSymbolString(i),
      MODE_SPREAD),"  margin at 1 lot=",MarginCalculate(GetSymbolString(i),1),
      "  MODE_TICKVALUE=",MarketInfo(GetSymbolString(i),MODE_TICKVALUE),
      ", MODE_TICKSIZE=",MarketInfo(GetSymbolString(i),MODE_TICKSIZE),
      " MODE_MARGINREQUIRED=",MarketInfo(GetSymbolString(i),MODE_MARGINREQUIRED));
     } 
//----
   return(0);
  }
//+------------------------------------------------------------------+

注）ほとんどの場合、シンボルのベース通貨は通貨ペアの最初のものですが、もちろんサーバー設定によりこの限りではありません。