iMA

Devuelve el manejador del indicador de la media móvil. Tiene sólo un búfer.

int  iMA(
   string               symbol,            // nombre del símbolo
   ENUM_TIMEFRAMES      period,            // período
   int                  ma_period,         // período promedio
   int                  ma_shift,          // desplazamiento horizontal del indicador
   ENUM_MA_METHOD       ma_method,         // tipo de suavizado
   ENUM_APPLIED_PRICE   applied_price      // tipo de precio o manejador
   );

Parámetros

symbol

[in]  Símbolo del instrumento financiero cuyos datos serán usados para calcular el indicador. NULL significa el símbolo actual.

period

[in]  Valor del período puede ser uno de los valores de la enumeración ENUM_TIMEFRAMES, 0 significa el timeframe actual.

ma_period

[in]  Período promedio para calcular la media móvil.

ma_shift

[in]  Desplazamiento del indicador con relación al gráfico de precios.

ma_method

[in]  Método de promedio. Puede obtener cualquier valor de ENUM_MA_METHOD.

applied_price

[in]  Precio que se usa. Puede ser cualquier precio de las constantes de precios ENUM_APPLIED_PRICE o un manejador de otro indicador.

Valor devuelto

Devuelve el manejador del indicador técnico especificado, en caso del fallo devuelve INVALID_HANDLE. Para liberar la memoria del ordenador del indicador que ya no se utiliza la función IndicatorRelease() a la que se le pasa el manejador (handle) de este indicador.

Ejemplo:

//+------------------------------------------------------------------+
//|                                                     Demo_iMA.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "El indicador demuestra cómo hay que obtener los datos"
#property description "de los búfers indicadores para el indicador técnico iMA."
#property description "El símbolo y el período de tiempo en el que se calcula el indicador"
#property description "se establecen mediante los parámetros symbol y period."
#property description "El modo de crear el manejador (handle) se establece mediante el parámetro 'type' (tipo de función)."
#property description "Todos los demás parámetros son iguales a los de la Moving Average estándar."
 
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1
//--- construcción de iMA
#property indicator_label1  "iMA"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//+------------------------------------------------------------------+
//|  Enumeración de modos de crear el manejador                      |
//+------------------------------------------------------------------+
enum Creation
  {
   Call_iMA,               // usar iMA
   Call_IndicatorCreate    // usar IndicatorCreate
  };
//--- parámetros de entrada
input Creation             type=Call_iMA;                // tipo de función 
input int                  ma_period=10;                 // período de la media
input int                  ma_shift=0;                   // desplazamiento
input ENUM_MA_METHOD       ma_method=MODE_SMA;           // tipo de suavizado
input ENUM_APPLIED_PRICE   applied_price=PRICE_CLOSE;    // tipo de precio
input string               symbol=" ";                   // símbolo 
input ENUM_TIMEFRAMES      period=PERIOD_CURRENT;        // timeframe
//--- búfer indicador
double         iMABuffer[];
//--- variable para guardar el manejador del indicador iMA
int    handle;
//--- variable para guardar
string name=symbol;
//--- nombre del indicador en el gráfico
string short_name;
//--- vamos a guardar el número de los valores en el indicador Moving Average
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- vinculación del array al búfer indicador
   SetIndexBuffer(0,iMABuffer,INDICATOR_DATA);
//--- fijaremos el desplazamiento
   PlotIndexSetInteger(0,PLOT_SHIFT,ma_shift);   
//--- determinamos el símbolo para el que se construye el indicador  
   name=symbol;
//--- eliminaremos los espacios del lado izquierdo y derecho
   StringTrimRight(name);
   StringTrimLeft(name);
//--- si después de eso la longitud de la cadena name obtiene el valor cero,
   if(StringLen(name)==0)
     {
      //--- cogeremos el símbolo del gráfico en el que está iniciado el indicador
      name=_Symbol;
     }
//--- crearemos el manejador del indicador
   if(type==Call_iMA)
      handle=iMA(name,period,ma_period,ma_shift,ma_method,applied_price);
   else
     {
      //--- llenaremos la estructura con los valores de los parámetros del indicador
      MqlParam pars[4];
      //--- período
      pars[0].type=TYPE_INT;
      pars[0].integer_value=ma_period;
      //--- desplazamiento
      pars[1].type=TYPE_INT;
      pars[1].integer_value=ma_shift;
      //--- tipo de suavizado
      pars[2].type=TYPE_INT;
      pars[2].integer_value=ma_method;
      //--- tipo de precio
      pars[3].type=TYPE_INT;
      pars[3].integer_value=applied_price;
      handle=IndicatorCreate(name,period,IND_MA,4,pars);
     }
//--- si no se puede crear el manejador
   if(handle==INVALID_HANDLE)
     {
      //--- avisaremos sobre el fallo y mostraremos el número del error
      PrintFormat("Fallo al crear el manejador del indicador iMA para el par %s/%s, código del error %d",
                  name,
                  EnumToString(period),
                  GetLastError());
      //--- el trabajo del indicador se finaliza anticipadamente
      return(INIT_FAILED);
     }
//--- mostraremos sobre qué par símbolo/período ha sido calculado el indicador Moving Average
   short_name=StringFormat("iMA(%s/%s, %d, %d, %s, %s)",name,EnumToString(period),
                           ma_period, ma_shift,EnumToString(ma_method),EnumToString(applied_price));
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- inicialización correcta del indicador
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- número de valores copiados desde el indicador iMA
   int values_to_copy;
//--- vamos a averiguar el número de valores calculados en el indicador
   int calculated=BarsCalculated(handle);
   if(calculated<=0)
     {
      PrintFormat("BarsCalculated() ha devuelto %d, el código del error %d",calculated,GetLastError());
      return(0);
     }
//--- si se trata del primer arranque del proceso de calculación de nuestro indicador o se ha cambiado el número de valores en el indicador iMA
//--- o si es necesario calcular el indicador para dos o más barras (entonces algo se ha cambiado en el historial)
   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
     {
      //--- si el array iMABuffer supera el número de valores en el indicador iMA sobre el par symbol/period, entonces no copiamos todo 
      //--- en caso contrario, copiaremos menos que el tamaño de los búfers indicadores
      if(calculated>rates_total) values_to_copy=rates_total;
      else                       values_to_copy=calculated;
     }
   else
     {
      //--- significa que no es la primera vez que se calcula nuestro indicador y desde el momento de la primera llamada de OnCalculate())
      //--- se ha añadido no más de una barra para la calculación
      values_to_copy=(rates_total-prev_calculated)+1;
     }
//--- llenamos el array iMABuffer con los valores desde el indicador Moving Average
//--- si FillArrayFromBuffer ha devuelto false, significa que los datos no están listos - entonces finalizamos el trabajo
   if(!FillArrayFromBuffer(iMABuffer,ma_shift,handle,values_to_copy)) return(0);
//--- creamos el mensaje
   string comm=StringFormat("%s ==>  Actualizados los valores en el indicador %s: %d",
                            TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                            short_name,
                            values_to_copy);
//--- mostraremos en el gráfico un mensaje de servicio
   Comment(comm);
//--- recordaremos el número de valores en el indicador Moving Average
   bars_calculated=calculated;
//--- devolveremos el valor prev_calculated para la siguiente llamada
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Llenamos el búfer indicador desde el indicador iMA               |
//+------------------------------------------------------------------+
bool FillArrayFromBuffer(double &values[],   // búfer indicador de valores Moving Average
                         int shift,          // desplazamiento
                         int ind_handle,     // manejador del indicador iMA
                         int amount          // número de valores a copiar
                         )
  {
//--- actualizaremos el código del error
   ResetLastError();
//--- llenamos una parte del array iMABuffer con los valores desde el búfer indicador con el índice 0
   if(CopyBuffer(ind_handle,0,-shift,amount,values)<0)
     {
      //--- si el proceso de copiado ha fallado, comunicaremos el código del error
      PrintFormat("Fallo al copiar los datos desde el indicador iMA, código del error %d",GetLastError());
      //--- finalizaremos con el resultado nulo - eso quiere decir que el indicador será considerado como no calculado
      return(false);
     }
//--- todo ha salido bien
   return(true);
  }
//+------------------------------------------------------------------+
//| Indicator deinitialization function                              |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   if(handle!=INVALID_HANDLE)
      IndicatorRelease(handle);
//--- limpiaremos el gráfico tras eliminar el indicador
   Comment("");
  }