Graphics in DoEasy library (Part 87): Graphical object collection - managing object property modification on all open charts
Artyom Trishkin | 24 November, 2021
Contents
- Concept
- Improving library classes
- Indicator sending messages about changes in object properties on all charts
- Handling indicator signals about object property change events
- Test
- What's next?
Concept
We are already able to control changes in standard graphical object properties built in the chart window the library-based program works on. To track some events, I have decided to use the event model in the previous article. Graphical object events are to be handled in the OnChartEvent() handler. This has greatly simplified the code (although the event handling is now located in two different library code blocks) and fixed the issue of incomplete filling of class object properties immediately when creating a graphical object on the chart. I mentioned this in the previous article.
All seems to be good but now we are unable to directly receive graphical object events from other charts. All events occurring on one chart arrive to OnChartEvent() handler of the program working on this particular chart. This means that in order to determine what event happened on the chart having no program, we need to send an event to the chart the program is launched on.
We are able to send a custom event to the program chart using the EventChartCustom() function.
The function can generate a custom event for a chart specified in it. At the same time, sending the event ID to the specified chart, the function automatically adds the CHARTEVENT_CUSTOM constant to its value. After receiving such an event in the library, we only need to subtract this added value from it to determine what kind of event happened on some other chart. To find the chart an event has occurred on, we can specify the chart ID in the long parameter of the lparam event. Now, after we see that lparam has a value (by default, lparam and dparam are equal to zero in case of graphical objects), we can already determine that the event has arrived from another chart — subtract the CHARTEVENT_CUSTOM value from the id parameter (also passed in the event) and get the event ID. The object the event occurred with can be determined via the sparam parameter since the object name is passed in it.
Thus, we are able to send events from other charts to the program chart. The event can be defined by the event ID (id), the chart is defined by the lparam parameter, while the object name — by the sparam parameter. Now we need to figure out how these events are to be managed on other charts since the program is launched on a single chart, while we should receive events and send them to the library and the program chart from other charts. The program should be able to work on these charts as well, while the library should be aware of it and be able to run it.
As you might remember, we have a small class to control events on different charts (CChartObjectsControl). In the collection class of graphical objects, we create the lists of all open charts of the client terminal set in the mentioned class parameters. In addition, the class also tracks changes in the number of graphical objects on the chart managed by the class object. Accordingly, inside the class, we are able to create a program for the chart controlled by the object and place the program on that chart. It is possible to use an indicator as the program. MQL5 allows creating a custom indicator directly in the program resources (so that the indicator remains its integral part after the compilation), creating an indicator handle for each of the charts opened in the terminal and, most pleasantly, programmatically placing a newly created indicator on the chart.
The indicator will not have drawn buffers. Its sole purpose is to track two graphical object events (CHARTEVENT_OBJECT_CHANGE and CHARTEVENT_OBJECT_DRAG) in the OnChartEvent() handler and send them to the program chart as a custom event we need to define and handle in the library.
Before implementing this, I would like to note that names of local variables for specifying the beginning of loops over library object properties have been changed in many library files. The variable name "beg" (abbreviation for "begin") looked incorrect for English-speaking users... Therefore, I decided to replace it with "begin" in all files.
Below are the library files, in which the variable has been renamed:
DataTick.mqh, Symbol.mqh, Bar.mqh, PendRequest.mqh, Order.mqh, MQLSignal.mqh, IndicatorDE.mqh, DataInd.mqh, Buffer.mqh, GCnvElement.mqh, Event.mqh, ChartWnd.mqh, ChartObj.mqh, MarketBookOrd.mqh, Account.mqh and GStdGraphObj.mqh.
Improving library classes
In \MQL5\Include\DoEasy\Data.mqh, add new message indices:
MSG_GRAPH_OBJ_TEXT_ANCHOR_LEFT_UPPER, // Anchor point at the upper left corner MSG_GRAPH_OBJ_TEXT_ANCHOR_LEFT, // Anchor point at the left center MSG_GRAPH_OBJ_TEXT_ANCHOR_LEFT_LOWER, // Anchor point at the lower left corner MSG_GRAPH_OBJ_TEXT_ANCHOR_LOWER, // Anchor point at the bottom center MSG_GRAPH_OBJ_TEXT_ANCHOR_RIGHT_LOWER, // Anchor point at the lower right corner MSG_GRAPH_OBJ_TEXT_ANCHOR_RIGHT, // Anchor point at the right center MSG_GRAPH_OBJ_TEXT_ANCHOR_RIGHT_UPPER, // Anchor point at the upper right corner MSG_GRAPH_OBJ_TEXT_ANCHOR_UPPER, // Anchor point at the upper center MSG_GRAPH_OBJ_TEXT_ANCHOR_CENTER, // Anchor point at the very center of the object //--- CGraphElementsCollection MSG_GRAPH_OBJ_FAILED_GET_ADDED_OBJ_LIST, // Failed to get the list of newly added objects MSG_GRAPH_OBJ_FAILED_DETACH_OBJ_FROM_LIST, // Failed to remove a graphical object from the list MSG_GRAPH_OBJ_CREATE_EVN_CTRL_INDICATOR, // Indicator for controlling and sending events created MSG_GRAPH_OBJ_FAILED_CREATE_EVN_CTRL_INDICATOR, // Failed to create the indicator for controlling and sending events MSG_GRAPH_OBJ_CLOSED_CHARTS, // Chart window closed: MSG_GRAPH_OBJ_OBJECTS_ON_CLOSED_CHARTS, // Objects removed together with charts: }; //+------------------------------------------------------------------+
and message texts corresponding to newly added indices:
{"Точка привязки в левом верхнем углу","Anchor point at the upper left corner"},
{"Точка привязки слева по центру","Anchor point to the left in the center"},
{"Точка привязки в левом нижнем углу","Anchor point at the lower left corner"},
{"Точка привязки снизу по центру","Anchor point below in the center"},
{"Точка привязки в правом нижнем углу","Anchor point at the lower right corner"},
{"Точка привязки справа по центру","Anchor point to the right in the center"},
{"Точка привязки в правом верхнем углу","Anchor point at the upper right corner"},
{"Точка привязки сверху по центру","Anchor point above in the center"},
{"Точка привязки строго по центру объекта","Anchor point strictly in the center of the object"},
//--- CGraphElementsCollection
{"Не удалось получить список вновь добавленных объектов","Failed to get the list of newly added objects"},
{"Не удалось изъять графический объект из списка","Failed to detach graphic object from the list"},
{"Создан индикатор контроля и отправки событий","An indicator for monitoring and sending events has been created"},
{"Не удалось создать индикатор контроля и отправки событий","Failed to create indicator for monitoring and sending events"},
{"Закрыто окон графиков: ","Closed chart windows: "},
{"С ними удалено объектов: ","Objects removed with them: "},
};
//+---------------------------------------------------------------------+
Symbol() method in \MQL5\Include\DoEasy\Objects\Graph\Standard\GStdGraphObj.mqh of the class of the abstract standard graphical object returns the Chart graphical object symbol:
//--- Symbol for the Chart object string Symbol(void) const { return this.GetProperty(GRAPH_OBJ_PROP_CHART_OBJ_SYMBOL); } void SetChartObjSymbol(const string symbol) { if(::ObjectSetString(CGBaseObj::ChartID(),CGBaseObj::Name(),OBJPROP_SYMBOL,symbol)) this.SetProperty(GRAPH_OBJ_PROP_CHART_OBJ_SYMBOL,symbol); }
Since all methods handling the Chart graphical object have the ChartObj prefix in their names, rename this method as well for consistency:
//--- Symbol for the Chart object string ChartObjSymbol(void) const { return this.GetProperty(GRAPH_OBJ_PROP_CHART_OBJ_SYMBOL); } void SetChartObjSymbol(const string symbol) { if(::ObjectSetString(CGBaseObj::ChartID(),CGBaseObj::Name(),OBJPROP_SYMBOL,symbol)) this.SetProperty(GRAPH_OBJ_PROP_CHART_OBJ_SYMBOL,symbol); } //--- Return the flags indicating object visibility on timeframes
Here we can see the already renamed variables I talked about at the very beginning:
//+------------------------------------------------------------------+ //| Compare CGStdGraphObj objects by all properties | //+------------------------------------------------------------------+ bool CGStdGraphObj::IsEqual(CGStdGraphObj *compared_obj) const { int begin=0, end=GRAPH_OBJ_PROP_INTEGER_TOTAL; for(int i=begin; i<end; i++) { ENUM_GRAPH_OBJ_PROP_INTEGER prop=(ENUM_GRAPH_OBJ_PROP_INTEGER)i; if(this.GetProperty(prop)!=compared_obj.GetProperty(prop)) return false; } begin=end; end+=GRAPH_OBJ_PROP_DOUBLE_TOTAL; for(int i=begin; i<end; i++) { ENUM_GRAPH_OBJ_PROP_DOUBLE prop=(ENUM_GRAPH_OBJ_PROP_DOUBLE)i; if(this.GetProperty(prop)!=compared_obj.GetProperty(prop)) return false; } begin=end; end+=GRAPH_OBJ_PROP_STRING_TOTAL; for(int i=begin; i<end; i++) { ENUM_GRAPH_OBJ_PROP_STRING prop=(ENUM_GRAPH_OBJ_PROP_STRING)i; if(this.GetProperty(prop)!=compared_obj.GetProperty(prop)) return false; } return true; } //+------------------------------------------------------------------+ //| Display object properties in the journal | //+------------------------------------------------------------------+ void CGStdGraphObj::Print(const bool full_prop=false,const bool dash=false) { ::Print("============= ",CMessage::Text(MSG_LIB_PARAMS_LIST_BEG)," (",this.Header(),") ============="); int begin=0, end=GRAPH_OBJ_PROP_INTEGER_TOTAL; for(int i=begin; i<end; i++) { ENUM_GRAPH_OBJ_PROP_INTEGER prop=(ENUM_GRAPH_OBJ_PROP_INTEGER)i; if(!full_prop && !this.SupportProperty(prop)) continue; ::Print(this.GetPropertyDescription(prop)); } ::Print("------"); begin=end; end+=GRAPH_OBJ_PROP_DOUBLE_TOTAL; for(int i=begin; i<end; i++) { ENUM_GRAPH_OBJ_PROP_DOUBLE prop=(ENUM_GRAPH_OBJ_PROP_DOUBLE)i; if(!full_prop && !this.SupportProperty(prop)) continue; ::Print(this.GetPropertyDescription(prop)); } ::Print("------"); begin=end; end+=GRAPH_OBJ_PROP_STRING_TOTAL; for(int i=begin; i<end; i++) { ENUM_GRAPH_OBJ_PROP_STRING prop=(ENUM_GRAPH_OBJ_PROP_STRING)i; if(!full_prop && !this.SupportProperty(prop)) continue; ::Print(this.GetPropertyDescription(prop)); } ::Print("============= ",CMessage::Text(MSG_LIB_PARAMS_LIST_END)," (",this.Header(),") =============\n"); } //+------------------------------------------------------------------+
...
//+------------------------------------------------------------------+ //| Check object property changes | //+------------------------------------------------------------------+ void CGStdGraphObj::PropertiesCheckChanged(void) { bool changed=false; int begin=0, end=GRAPH_OBJ_PROP_INTEGER_TOTAL; for(int i=begin; i<end; i++) { ENUM_GRAPH_OBJ_PROP_INTEGER prop=(ENUM_GRAPH_OBJ_PROP_INTEGER)i; if(!this.SupportProperty(prop)) continue; if(this.GetProperty(prop)!=this.GetPropertyPrev(prop)) { changed=true; ::Print(DFUN,this.Name(),": ",TextByLanguage(" Изменённое свойство: "," Modified property: "),GetPropertyDescription(prop)); } } begin=end; end+=GRAPH_OBJ_PROP_DOUBLE_TOTAL; for(int i=begin; i<end; i++) { ENUM_GRAPH_OBJ_PROP_DOUBLE prop=(ENUM_GRAPH_OBJ_PROP_DOUBLE)i; if(!this.SupportProperty(prop)) continue; if(this.GetProperty(prop)!=this.GetPropertyPrev(prop)) { changed=true; ::Print(DFUN,this.Name(),": ",TextByLanguage(" Изменённое свойство: "," Modified property: "),GetPropertyDescription(prop)); } } begin=end; end+=GRAPH_OBJ_PROP_STRING_TOTAL; for(int i=begin; i<end; i++) { ENUM_GRAPH_OBJ_PROP_STRING prop=(ENUM_GRAPH_OBJ_PROP_STRING)i; if(!this.SupportProperty(prop)) continue; if(this.GetProperty(prop)!=this.GetPropertyPrev(prop)) { changed=true; ::Print(DFUN,this.Name(),": ",TextByLanguage(" Изменённое свойство: "," Modified property: "),GetPropertyDescription(prop)); } } if(changed) PropertiesCopyToPrevData(); } //+------------------------------------------------------------------+
Indicator sending messages about changes in object properties on all charts
Let's define the parameters of the indicator which is to track events of graphical objects of the chart it is to be attached to.
The indicator should know:
- ID of the chart it is launched on (let's call it SourseID) and
- ID of the chart it should send custom events to (DestinationID).
If we simply launch the indicator on the chart manually (i.e. find it in the navigator and drag it to the chart symbol), the ChartID() function, returning the ID of the current chart, returns the ID of the chart the indicator is launched on. At first glance, this is exactly what we need. But... If the indicator is in the program resources (it is built into the program code during compilation and launched from the built-in resource), the ChartID() function returns the ID of the chart the program is launched on rather than the indicator instance. In other words, we cannot find out the ID of the chart the indicator is launched on by programmatically launching the indicator on different charts if the indicator is launched from the folder other than Indicators\. The solution here is to pass the current chart ID in the indicator settings since we have the lists of IDs of all charts opened in the client terminal.
In the editor navigator (namely, in \MQL5\Indicators\), create a new folder DoEasy\
with a new custom indicator EventControl.mq5.
While creating, specify two inputs of long type with the initial value of 0:
At the next step of the wizard, set the need to include the OnChartEvent() handler to the indicator code by ticking the appropriate checkbox:
At the next step, leave all fields and checkboxes empty and click Finish:
The indicator is created.
If we compile it now, we will get a warning that the indicator does not have a single drawn buffer:
To avoid this warning, we need to explicitly specify that we do not need drawn buffers in the indicator code:
//+------------------------------------------------------------------+ //| EventControl.mq5 | //| Copyright 2021, MetaQuotes Ltd. | //| https://mql5.com/en/users/artmedia70 | //+------------------------------------------------------------------+ #property copyright "Copyright 2021, MetaQuotes Ltd." #property link "https://mql5.com/en/users/artmedia70" #property version "1.00" #property indicator_chart_window #property indicator_plots 0 //--- input parameters input long InpChartSRC = 0; input long InpChartDST = 0; //+------------------------------------------------------------------+ //| Custom indicator initialization function | //+------------------------------------------------------------------+
When deinitializing the library classes, we need to remove the launched indicator from all open charts. Since we can find the indicator by its short name, we need to explicitly set the name in the indicator OnInit() handler to find and remove the indicator from the chart:
//+------------------------------------------------------------------+ //| Custom indicator initialization function | //+------------------------------------------------------------------+ int OnInit() { //--- indicator shortname IndicatorSetString(INDICATOR_SHORTNAME,"EventSend_From#"+(string)InpChartSRC+"_To#"+(string)InpChartDST); //--- return(INIT_SUCCEEDED); } //+------------------------------------------------------------------+
The short name will contain:
- indicator name: "EventSend",
- ID of the chart the message is sent from: "_From#"+(string)InpChartSRC and
- ID of the chart the message is sent to: "_To#"+(string)InpChartDST.
In the OnCalculate() handler, we do nothing — simply return the number of chart bars:
//+------------------------------------------------------------------+ //| Custom indicator iteration function | //+------------------------------------------------------------------+ int OnCalculate(const int rates_total, const int prev_calculated, const datetime &time[], const double &open[], const double &high[], const double &low[], const double &close[], const long &tick_volume[], const long &volume[], const int &spread[]) { return rates_total; } //+------------------------------------------------------------------+
In the OnChartEvent() handler of the indicator, track two graphical object events (CHARTEVENT_OBJECT_CHANGE and CHARTEVENT_OBJECT_DRAG). If they are detected, send a custom event to the control program chart:
//+------------------------------------------------------------------+ //| ChartEvent function | //+------------------------------------------------------------------+ void OnChartEvent(const int id, const long &lparam, const double &dparam, const string &sparam) { //--- if(id==CHARTEVENT_OBJECT_CHANGE || id==CHARTEVENT_OBJECT_DRAG) { EventChartCustom(InpChartDST,(ushort)id,InpChartSRC,dparam,sparam); } } //+------------------------------------------------------------------+
In the message itself, specify the chart the event is sent to, event ID (the EventChartCustom() function automatically adds the CHARTEVENT_CUSTOM value to the event value), ID of the chart the event is sent from and two remaining default values — dparam will be equal to zero, while sparam sets the name of the graphical object the changes have occurred at.
Compile the indicator and leave it in its folder. We are going to access it from the library. We will need it only when compiling the library, which will place it in its resources and access the indicator instance stored in the resources later on.
When distributing the compiled program, there is no more need in passing either the source code or the compiled file of the indicator since the indicator code will be embedded into the program code when compiling the program and the program will access the code when necessary.
The indicator file can be found in the attachments below.
Now we need to create a resource the executable indicator code is to be stored at.
In \MQL5\Include\DoEasy\Defines.mqh, define the macro substitution for specifying the path to the indicator executable file:
//+------------------------------------------------------------------+ //| Defines.mqh | //| Copyright 2021, MetaQuotes Software Corp. | //| https://mql5.com/en/users/artmedia70 | //+------------------------------------------------------------------+ #property copyright "Copyright 2021, MetaQuotes Software Corp." #property link "https://mql5.com/en/users/artmedia70" //+------------------------------------------------------------------+ //| Include files | //+------------------------------------------------------------------+ #include "DataSND.mqh" #include "DataIMG.mqh" #include "Data.mqh" #ifdef __MQL4__ #include "ToMQL4.mqh" #endif //+------------------------------------------------------------------+ //| Resources | //+------------------------------------------------------------------+ #define PATH_TO_EVENT_CTRL_IND "Indicators\\DoEasy\\EventControl.ex5" //+------------------------------------------------------------------+ //| Macro substitutions | //+------------------------------------------------------------------+
Using this macro substitution, we will obtain the path to the compiled indicator file in the library resources.
Let's add the list of possible graphical object events to the same file:
//+------------------------------------------------------------------+ //| Data for handling graphical elements | //+------------------------------------------------------------------+ //+------------------------------------------------------------------+ //| List of possible graphical object events | //+------------------------------------------------------------------+ enum ENUM_GRAPH_OBJ_EVENT { GRAPH_OBJ_EVENT_NO_EVENT = CHART_OBJ_EVENTS_NEXT_CODE,// No event GRAPH_OBJ_EVENT_CREATE, // "Creating a new graphical object" event GRAPH_OBJ_EVENT_CHANGE, // "Changing graphical object properties" event GRAPH_OBJ_EVENT_MOVE, // "Moving graphical object" event GRAPH_OBJ_EVENT_RENAME, // "Renaming graphical object" event GRAPH_OBJ_EVENT_DELETE, // "Removing graphical object" event }; #define GRAPH_OBJ_EVENTS_NEXT_CODE (GRAPH_OBJ_EVENT_DELETE+1) // The code of the next event after the last graphical object event code //+------------------------------------------------------------------+ //| List of anchoring methods | //| (horizontal and vertical text alignment) | //+------------------------------------------------------------------+
This enumeration contains a preliminary list of events to be sent to the program when creating a unified functionality for controlling events of standard graphical objects I am going to introduce in the near future.
Handling indicator signals about object property change events
When opening new chart windows, the library automatically creates instances of objects of the class for managing CChartObjectsControl chart objects and saves them to the chart management object list in the graphical object collection class.
The object for managing the chart objects stores the managed chart ID in its properties. Accordingly, we can create an indicator for controlling the events of graphical objects in the same object when creating it for the chart window. Thus, we will be able to place our new indicator to each newly opened chart (or to existing ones during the first launch). The indicator will track graphical object events and send them to the control program chart.
In the private section of the CChartObjectsControl class in \MQL5\Include\DoEasy\Collections\GraphElementsCollection.mqh, declare three new variables:
//+------------------------------------------------------------------+ //| Chart object management class | //+------------------------------------------------------------------+ class CChartObjectsControl : public CObject { private: CArrayObj m_list_new_graph_obj; // List of added graphical objects ENUM_TIMEFRAMES m_chart_timeframe; // Chart timeframe long m_chart_id; // Chart ID long m_chart_id_main; // Control program chart ID string m_chart_symbol; // Chart symbol bool m_is_graph_obj_event; // Event flag in the list of graphical objects int m_total_objects; // Number of graphical objects int m_last_objects; // Number of graphical objects during the previous check int m_delta_graph_obj; // Difference in the number of graphical objects compared to the previous check int m_handle_ind; // Event controller indicator handle string m_name_ind; // Short name of the event controller indicator //--- Return the name of the last graphical object added to the chart string LastAddedGraphObjName(void); //--- Set the permission to track mouse events and graphical objects void SetMouseEvent(void); public:
The functions of the variables are clear from their descriptions.
In the public section of the class, declare two new methods for creating an indicator and adding it to the chart:
public: //--- Return the variable values ENUM_TIMEFRAMES Timeframe(void) const { return this.m_chart_timeframe; } long ChartID(void) const { return this.m_chart_id; } string Symbol(void) const { return this.m_chart_symbol; } bool IsEvent(void) const { return this.m_is_graph_obj_event; } int TotalObjects(void) const { return this.m_total_objects; } int Delta(void) const { return this.m_delta_graph_obj; } //--- Create a new standard graphical object CGStdGraphObj *CreateNewGraphObj(const ENUM_OBJECT obj_type,const long chart_id, const string name); //--- Return the list of newly added objects CArrayObj *GetListNewAddedObj(void) { return &this.m_list_new_graph_obj;} //--- Create the event control indicator bool CreateEventControlInd(const long chart_id_main); //--- Add the event control indicator to the chart bool AddEventControlInd(void); //--- Check the chart objects void Refresh(void); //--- Constructors
In the class constructors, set the default values to new variables and add the class destructor removing the indicator on the chart and the indicator handle while releasing the calculation part of the indicator:
//--- Check the chart objects void Refresh(void); //--- Constructors CChartObjectsControl(void) { this.m_list_new_graph_obj.Clear(); this.m_list_new_graph_obj.Sort(); this.m_chart_id=::ChartID(); this.m_chart_timeframe=(ENUM_TIMEFRAMES)::ChartPeriod(this.m_chart_id); this.m_chart_symbol=::ChartSymbol(this.m_chart_id); this.m_chart_id_main=::ChartID(); this.m_is_graph_obj_event=false; this.m_total_objects=0; this.m_last_objects=0; this.m_delta_graph_obj=0; this.m_name_ind=""; this.m_handle_ind=INVALID_HANDLE; this.SetMouseEvent(); } CChartObjectsControl(const long chart_id) { this.m_list_new_graph_obj.Clear(); this.m_list_new_graph_obj.Sort(); this.m_chart_id=chart_id; this.m_chart_timeframe=(ENUM_TIMEFRAMES)::ChartPeriod(this.m_chart_id); this.m_chart_symbol=::ChartSymbol(this.m_chart_id); this.m_chart_id_main=::ChartID(); this.m_is_graph_obj_event=false; this.m_total_objects=0; this.m_last_objects=0; this.m_delta_graph_obj=0; this.m_name_ind=""; this.m_handle_ind=INVALID_HANDLE; this.SetMouseEvent(); } //--- Destructor ~CChartObjectsControl() { ::ChartIndicatorDelete(this.ChartID(),0,this.m_name_ind); ::IndicatorRelease(this.m_handle_ind); } //--- Compare CChartObjectsControl objects by a chart ID (for sorting the list by an object property) virtual int Compare(const CObject *node,const int mode=0) const { const CChartObjectsControl *obj_compared=node; return(this.ChartID()>obj_compared.ChartID() ? 1 : this.ChartID()<obj_compared.ChartID() ? -1 : 0); } //--- Event handler void OnChartEvent(const int id, const long &lparam, const double &dparam, const string &sparam); }; //+------------------------------------------------------------------+
Implement declared methods outside the class body.
The method creating the event control indicator:
//+------------------------------------------------------------------+ //| CChartObjectsControl: Create the event control indicator | //+------------------------------------------------------------------+ bool CChartObjectsControl::CreateEventControlInd(const long chart_id_main) { this.m_chart_id_main=chart_id_main; string name="::"+PATH_TO_EVENT_CTRL_IND; ::ResetLastError(); this.m_handle_ind=::iCustom(this.Symbol(),this.Timeframe(),name,this.ChartID(),this.m_chart_id_main); if(this.m_handle_ind==INVALID_HANDLE) { CMessage::ToLog(DFUN,MSG_GRAPH_OBJ_FAILED_CREATE_EVN_CTRL_INDICATOR); CMessage::ToLog(DFUN,::GetLastError(),true); return false; } this.m_name_ind="EventSend_From#"+(string)this.ChartID()+"_To#"+(string)this.m_chart_id_main; Print ( DFUN,this.Symbol()," ",TimeframeDescription(this.Timeframe()),": ", CMessage::Text(MSG_GRAPH_OBJ_CREATE_EVN_CTRL_INDICATOR)," \"",this.m_name_ind,"\"" ); return true; } //+------------------------------------------------------------------+
Here we set the control program ID passed in the method parameters, set the path to our indicator in the resources and create the indicator handle based on a symbol and timeframe of the chart controlled by the class.
Pass the ID of the chart, controlled by the class object and control program ID to the indicator inputs.
If failed to create the indicator, inform of that in the terminal journal specifying the error index and description, and return false.
If the indicator handle is created, specify the short name used to remove the indicator from the chart in the class destructor, display the journal message about creating the indicator on the chart and return true.
Note that we specify the context resolution sign "::" before the path string when specifying the path to the indicator in the library resources.
In contrast, when creating a resource, we set "\\".
The method adding the event control indicator to the chart:
//+------------------------------------------------------------------+ //|CChartObjectsControl: Add the event control indicator to the chart| //+------------------------------------------------------------------+ bool CChartObjectsControl::AddEventControlInd(void) { if(this.m_handle_ind==INVALID_HANDLE) return false; return ::ChartIndicatorAdd(this.ChartID(),0,this.m_handle_ind); } //+------------------------------------------------------------------+
Here we check the indicator handle. If it is invalid, return false. Otherwise, return the operation result of the function for adding the indicator to the chart.
Before defining the graphical object collection class, set the path to the resource storing the indicator:
//+------------------------------------------------------------------+ //| Collection of graphical objects | //+------------------------------------------------------------------+ #resource "\\"+PATH_TO_EVENT_CTRL_IND; // Indicator for controlling graphical object events packed into the program resources class CGraphElementsCollection : public CBaseObj {
This string creates the library resource containing the compiled executable indicator file for controlling chart events.
In the private section of the class, declare four new methods:
class CGraphElementsCollection : public CBaseObj { private: CArrayObj m_list_charts_control; // List of chart management objects CListObj m_list_all_canv_elm_obj; // List of all graphical elements on canvas CListObj m_list_all_graph_obj; // List of all graphical objects bool m_is_graph_obj_event; // Event flag in the list of graphical objects int m_total_objects; // Number of graphical objects int m_delta_graph_obj; // Difference in the number of graphical objects compared to the previous check //--- Return the flag indicating the graphical element class object presence in the collection list of graphical elements bool IsPresentGraphElmInList(const int id,const ENUM_GRAPH_ELEMENT_TYPE type_obj); //--- Return the flag indicating the presence of the graphical object class in the graphical object collection list bool IsPresentGraphObjInList(const long chart_id,const string name); //--- Return the flag indicating the presence of a graphical object on a chart by name bool IsPresentGraphObjOnChart(const long chart_id,const string name); //--- Return the pointer to the object of managing objects of the specified chart CChartObjectsControl *GetChartObjectCtrlObj(const long chart_id); //--- Create a new object of managing graphical objects of a specified chart and add it to the list CChartObjectsControl *CreateChartObjectCtrlObj(const long chart_id); //--- Update the list of graphical objects by chart ID CChartObjectsControl *RefreshByChartID(const long chart_id); //--- Check if the chart window is present bool IsPresentChartWindow(const long chart_id); //--- Handle removing the chart window void RefreshForExtraObjects(void); //--- Return the first free ID of the graphical (1) object and (2) element on canvas long GetFreeGraphObjID(void); long GetFreeCanvElmID(void); //--- Add a graphical object to the collection bool AddGraphObjToCollection(const string source,CChartObjectsControl *obj_control); //--- Find an object present in the collection but not on a chart CGStdGraphObj *FindMissingObj(const long chart_id); //--- Find the graphical object present on a chart but not in the collection string FindExtraObj(const long chart_id); //--- Remove the graphical object from the graphical object collection list: (1) specified object, (2) by chart ID bool DeleteGraphObjFromList(CGStdGraphObj *obj); void DeleteGraphObjectsFromList(const long chart_id); //--- Remove the object of managing charts from the list bool DeleteGraphObjCtrlObjFromList(CChartObjectsControl *obj); public:
In order to remove unnecessary chart control objects from the class list and objects describing remote graphical objects from the collection list, we need to know that a certain chart has been deleted. The IsPresentChartWindow() method will be used for that. The RefreshForExtraObjects() method handles the presence of unnecessary objects in the collection class lists, while the DeleteGraphObjectsFromList() and DeleteGraphObjCtrlObjFromList() methods will delete the specified objects from the lists of the graphical object collection list.
In the method creating a new object of managing graphical objects of a specified chart, add the code for creating an indicator and adding it to the chart:
//+------------------------------------------------------------------+ //| Create a new graphical object management object | //| for a specified and add it to the list | //+------------------------------------------------------------------+ CChartObjectsControl *CGraphElementsCollection::CreateChartObjectCtrlObj(const long chart_id) { //--- Create a new object for managing chart objects by ID CChartObjectsControl *obj=new CChartObjectsControl(chart_id); //--- If the object is not created, inform of the error and return NULL if(obj==NULL) { ::Print(DFUN,CMessage::Text(MSG_GRAPH_ELM_COLLECTION_ERR_FAILED_CREATE_CTRL_OBJ),(string)chart_id); return NULL; } //--- If failed to add the object to the list, inform of the error, remove the object and return NULL if(!this.m_list_charts_control.Add(obj)) { CMessage::ToLog(DFUN,MSG_LIB_SYS_FAILED_OBJ_ADD_TO_LIST); delete obj; return NULL; } if(obj.ChartID()!=CBaseObj::GetMainChartID() && obj.CreateEventControlInd(CBaseObj::GetMainChartID())) obj.AddEventControlInd(); //--- Return the pointer to the object that was created and added to the list return obj; } //+------------------------------------------------------------------+
Here we make sure that the control object is created not for the current chart the program currently works on and that the indicator is successfully created for the chart controlled by the chart management object. If all is correct, add the newly created indicator to the chart.
In the method updating the list of all graphical objects, first handle closing charts in the terminal to remove the chart management objects corresponding to removed charts, as well as class objects describing graphical objects which became unnecessary in the collection list after closing the chart and were removed together with the charts:
//+------------------------------------------------------------------+ //| Update the list of all graphical objects | //+------------------------------------------------------------------+ void CGraphElementsCollection::Refresh(void) { this.RefreshForExtraObjects(); //--- Declare variables to search for charts long chart_id=0; int i=0; //--- In the loop by all open charts in the terminal (no more than 100) while(i<CHARTS_MAX) { //--- Get the chart ID chart_id=::ChartNext(chart_id); if(chart_id<0) break; //--- Get the pointer to the object for managing graphical objects //--- and update the list of graphical objects by chart ID CChartObjectsControl *obj_ctrl=this.RefreshByChartID(chart_id); //--- If failed to get the pointer, move on to the next chart if(obj_ctrl==NULL) continue; //--- If the number of objects on the chart changes if(obj_ctrl.IsEvent()) { //--- If a graphical object is added to the chart if(obj_ctrl.Delta()>0) { //--- Get the list of added graphical objects and move them to the collection list //--- (if failed to move the object to the collection, move on to the next object) if(!AddGraphObjToCollection(DFUN_ERR_LINE,obj_ctrl)) continue; } //--- If the graphical object has been removed else if(obj_ctrl.Delta()<0) { // Find an extra object in the list CGStdGraphObj *obj=this.FindMissingObj(chart_id); if(obj!=NULL) { //--- Display a short description of a detected object deleted from a chart in the journal obj.PrintShort(); //--- Remove the class object of a removed graphical object from the collection list if(!this.DeleteGraphObjFromList(obj)) CMessage::ToLog(DFUN,MSG_GRAPH_OBJ_FAILED_DETACH_OBJ_FROM_LIST); } } } //--- Increase the loop index i++; } } //+------------------------------------------------------------------+
The method checking the presence of the chart window:
//+------------------------------------------------------------------+ //| Check if the chart window is present | //+------------------------------------------------------------------+ bool CGraphElementsCollection::IsPresentChartWindow(const long chart_id) { long chart=0; int i=0; //--- In the loop by all open charts in the terminal (no more than 100) while(i<CHARTS_MAX) { //--- Get the chart ID chart=::ChartNext(chart); if(chart<0) break; if(chart==chart_id) return true; //--- Increase the loop index i++; } return false; } //+------------------------------------------------------------------+
Here we get the ID of the next chart and compare it with the one passed to the method in the loop by all open charts.
If the IDs match, then the chart is present. Return true.
Upon the loop completion, return false — there is no chart with the specified ID.
The method handling the chart window deletion:
//+------------------------------------------------------------------+ //| Handle removing the chart window | //+------------------------------------------------------------------+ void CGraphElementsCollection::RefreshForExtraObjects(void) { for(int i=this.m_list_charts_control.Total()-1;i>WRONG_VALUE;i--) { CChartObjectsControl *obj_ctrl=this.m_list_charts_control.At(i); if(obj_ctrl==NULL) continue; if(!this.IsPresentChartWindow(obj_ctrl.ChartID())) { long chart_id=obj_ctrl.ChartID(); int total_ctrl=m_list_charts_control.Total(); this.DeleteGraphObjCtrlObjFromList(obj_ctrl); int total_obj=m_list_all_graph_obj.Total(); this.DeleteGraphObjectsFromList(chart_id); int del_ctrl=total_ctrl-m_list_charts_control.Total(); int del_obj=total_obj-m_list_all_graph_obj.Total(); Print ( DFUN,CMessage::Text(MSG_GRAPH_OBJ_CLOSED_CHARTS),(string)del_ctrl,". ", CMessage::Text(MSG_GRAPH_OBJ_OBJECTS_ON_CLOSED_CHARTS),(string)del_obj ); } } } //+------------------------------------------------------------------+
Here in the loop by the list of chart management objects, get the next object. If the terminal contains no chart corresponding to the object, this means the chart has been closed.
So we get the ID of the closed chart, as well as the total number of previously opened charts, and remove the control object corresponding to the already closed chart from the list.
Get the total number of graphical objects present in the terminal before removing the chart and remove the objects of graphical object classes, that were present on the now closed chart, from the collection list.
Next, calculate the number of closed charts and the number of graphical objects removed with the charts, as well as display the journal message regarding the number of closed charts and graphical objects on them.
Later this message will be replaced with creating an event and sending it to the control program chart.
The method removing the graphical object from the graphical object collection list by a chart ID:
//+------------------------------------------------------------------+ //| Remove a graphical object by a chart ID | //| from the graphical object collection list | //+------------------------------------------------------------------+ void CGraphElementsCollection::DeleteGraphObjectsFromList(const long chart_id) { CArrayObj *list=CSelect::ByGraphicStdObjectProperty(GetListGraphObj(),GRAPH_OBJ_PROP_CHART_ID,chart_id,EQUAL); if(list==NULL) return; for(int i=list.Total();i>WRONG_VALUE;i--) { CGStdGraphObj *obj=list.At(i); if(obj==NULL) continue; this.DeleteGraphObjFromList(obj); } } //+------------------------------------------------------------------+
Here we receive the list of graphical objects with the specified chart ID. In the loop by the obtained list, get the next object and remove it from the collection list.
The method removing the chart management object from the list:
//+------------------------------------------------------------------+ //| Remove the object of managing charts from the list | //+------------------------------------------------------------------+ bool CGraphElementsCollection::DeleteGraphObjCtrlObjFromList(CChartObjectsControl *obj) { this.m_list_charts_control.Sort(); int index=this.m_list_charts_control.Search(obj); return(index==WRONG_VALUE ? false : m_list_charts_control.Delete(index)); } //+------------------------------------------------------------------+
Here we set the sorted list flag for the list of chart management objects and use the Search() method to find the index of the specified object in the list. If the object is not in the list, return false. Otherwise, return the result of the Delete() method operation.
In the handler of graphical object collection class events, replace working with the current chart with handling the chart by its ID. To achieve this, let's manage the lparam value in an event. It will be zero when receiving an event from the current chart and will be equal to the ID of the chart the event arrives from when a custom event is received from the indicator.
In order to receive the graphical object event ID from the custom event, we need to subtract CHARTEVENT_CUSTOM from the obtained id value and check the calculated event ID in idx together with the id check.
If lparam is not zero, the event has been received not from the current chart. Otherwise, it has been received from the current one.
Now it only remains to replace all instances of ::ChartID() with the obtained chart_id in the code:
//+------------------------------------------------------------------+ //| Event handler | //+------------------------------------------------------------------+ void CGraphElementsCollection::OnChartEvent(const int id, const long &lparam, const double &dparam, const string &sparam) { CGStdGraphObj *obj=NULL; ushort idx=ushort(id-CHARTEVENT_CUSTOM); if(id==CHARTEVENT_OBJECT_CHANGE || id==CHARTEVENT_OBJECT_DRAG || idx==CHARTEVENT_OBJECT_CHANGE || idx==CHARTEVENT_OBJECT_DRAG) { //--- Get the chart ID. If lparam is zero, //--- the event is from the current chart, //--- otherwise, this is a custom event from an indicator long chart_id=(lparam==0 ? ::ChartID() : lparam); //--- If the object, whose properties were changed or which was relocated, //--- is successfully received from the collection list by its name set in sparam obj=this.GetStdGraphObject(sparam,chart_id); if(obj!=NULL) { //--- Update the properties of the obtained object //--- and check their change obj.PropertiesRefresh(); obj.PropertiesCheckChanged(); } //--- If failed to get the object by its name, it is not on the list, //--- which means its name has been changed else { //--- Let's search the list for the object that is not on the chart obj=this.FindMissingObj(chart_id); if(obj==NULL) return; //--- Get the name of the renamed graphical object on the chart, which is not in the collection list string name_new=this.FindExtraObj(chart_id); //--- Set a new name for the collection list object, which does not correspond to any graphical object on the chart, //--- update the chart properties and check their change obj.SetName(name_new); obj.PropertiesRefresh(); obj.PropertiesCheckChanged(); } } } //+------------------------------------------------------------------+
These are all the improvements we currently need. Let's test the obtained result.
Test
To perform the test, let's use the EA from the previous article and save it to \MQL5\Experts\TestDoEasy\Part87\ as TestDoEasyPart87.mq5.
The EA remains unchanged. Simply compile and launch it on the chart, while preliminarily opening two more charts in the terminal. When creating and changing objects on additional charts, all events occurring to graphical objects are recorded by the library and appropriate messages are displayed in the journal. When opening yet another chart, the chart control object is created for it as well together with the indicator registering object change events and sending them to the library. When removing additional charts, the appropriate entries are displayed in the journal:
What's next?
In the next article, I will start putting together handling graphical objects so that all events occurring to graphical objects on open charts are sent to the control program chart (currently, registered events are simply displayed in the journal but the library-controlled program is not aware of them).
Leave your questions, comments and suggestions in the comments.
*Previous articles within the series:
Graphics in DoEasy library (Part 83): Class of the abstract standard graphical object
Graphics in DoEasy library (Part 84): Descendant classes of the abstract standard graphical object
Graphics in DoEasy library (Part 85): Graphical object collection - adding newly created objects
Graphics in DoEasy library (Part 86): Graphical object collection - managing property modification