#property copyright "Integer"
#property link      "for-good-letters@yandex.ru"

int start(){
   
   // Подготовка массива заголовков
   string Header[5]={" "/*левая колонка используется для нумерации строк*/,"Колонка 1","Колонка 2","Колонка 3","Колонка 4"};

   // Подготовка массива с содержимым таблицы   
   string Content[10][5];
      for(int i=0;i<10;i++){
            for(int j=1;j<5;j++){
               Content[i][j]="Колонка - "+j+", строка - "+i;
            }   
         Content[i][0]=i+1; // номера сторок
      }
   
   // Формирование таблицы
   string str= fHTML_Table(Header,Content);
   
   // Сохранение файла
   int h=FileOpen("HTML_Example.htm",FILE_CSV|FILE_WRITE);
   FileWrite(h,str);
   FileClose(h);
   
   
  
//----
   return(0);
  }
//+------------------------------------------------------------------+
string fHTML_Table(        string   aHeader[],                             // Массив с заголовками колонок. Размер массива определяет количество колонок таблицы
                           string   aContent[][],                          // Массив с содержимым таблицы. Первое измерение - строка, второе - колонка
                           bool     aLeftBold         =  true,             // Выводить левую колонку жирным шрифтом
                           bool     aHeaderFlag       =  true,             // Выводить заголовок. Даже если вывод заголовка не используется, всеравно необходимо определять размер массива aHeader
                           bool     aColorAltFlag     =  true,             // Чередовать цвета строк таблицы               
                           string   aFontFace         =  "Tahoma",         // Шрифт
                           int      aFontSize         =  1,                // Размер шрифта
                           int      aBorderSize       =  0,                // Ширина рамки
                           int      aCellPadding      =  2,                // Отсутп текста от края ячейки
                           int      aCellSpacing      =  1,                // Пространство между ячейками
                           string   aFontColor        =  "#000000",        // Цвет текста
                           string   aBorderColor      =  "#FFFFFF",        // Цвет рамки   
                           string   aHeaderColor      =  "#C0C0C0",        // Цвет фона заголовка
                           string   aRowColor_1       =  "#FFFFFF",        // Цвет 1 строк таблицы
                           string   aRowColor_2       =  "#E0E0E0"         // Цвет 2 строк таблицы
                           ){
   string tRetStr="<table border=1 bordercolor="+aHeaderColor+" cellpadding=0 cellspacing=0><tr><td>\n";                           
   tRetStr=tRetStr+"<table border="+aBorderSize+" bordercolor="+aBorderColor+" cellpadding="+aCellPadding+" cellspacing="+aCellSpacing+">\n";
      if(aHeaderFlag){
         tRetStr=tRetStr+"<tr bgcolor="+aHeaderColor+">";
            for(int tj=0;tj<ArraySize(aHeader);tj++){
               tRetStr=tRetStr+"<td><b><p align=center><font face="+aFontFace+" size="+aFontSize+" color="+aFontColor+">"+aHeader[tj]+"</font></p></b></td>\n";
            }
         tRetStr=tRetStr+"</tr>\n";
      }
   string tColor=aRowColor_1;   
      for(int ti=0;ti<ArraySize(aContent)/ArraySize(aHeader);ti++){
         tRetStr=tRetStr+"<tr bgcolor="+tColor+">\n";
            for(tj=0;tj<ArraySize(aHeader);tj++){
               string tStr=aContent[ti][tj];
                  if(tj==0){
                     if(aLeftBold){
                        tStr="<b>"+tStr+"</b>\n";
                     }
                  }
                  tRetStr=tRetStr+"<td><p align=right><font face="+aFontFace+" size="+aFontSize+" color="+aFontColor+">"+tStr+"</font></p></td>\n";
            }
         tRetStr=tRetStr+"</tr>\n";
            if(aColorAltFlag){
               if(tColor==aRowColor_1){
                  tColor=aRowColor_2;               
               }
               else{
                  tColor=aRowColor_1;
               }
            }
      }
   tRetStr=tRetStr+"</table></td></tr></table>\n";   
   return(tRetStr);
}